Консольная команда изгнания пользователей

>executor.cmd .\service_bases.sbsl::DropSessions -Сервер "server" -База "basename"
service_bases.sbsl
конст ВЕРСИЯ = "1.0.0.0"

метод Скрипт()
    Консоль.Записать("Весрия скрипта: %ВЕРСИЯ\нЗдесь будет версия и помощь по скрипту")
;

метод DropSessions(Сервер: Строка, База: Строка)
    Консоль.Записать("Сервер: %Сервер База: %База Удаляем сессии...")
    знч АдминистрированиеСервера = новый АдминистрированиеСервераV8(Сервер, 1545)
    знч Кластеры = АдминистрированиеСервера.ПолучитьКластеры()
    для Кластер из Кластеры 
        Консоль.Записать(" Кластер: %Кластер")
        Кластер.ВыполнитьАутентификацию()
        знч ИнформационныеБазы = Кластер.ПолучитьИнфобазы()
        для ИнформационнаяБазаОписание из ИнформационныеБазы
            Консоль.Записать("  ИБ: %{ИнформационнаяБазаОписание.Имя}")
            если ИнформационнаяБазаОписание.Имя == База
                знч ИнформационнаяБаза = ИнформационнаяБазаОписание.ВыполнитьАутентификацию("Пользователь","Пароль")
                
                знч Сеансы = ИнформационнаяБаза.ПолучитьСеансы()
                для Сеанс из Сеансы
                    если Сеанс.ИмяПриложения == "1CV8C"
                        Консоль.Записать("     (-) Сеанс: %{Сеанс.ИмяПриложения} ИмяПользователя: %{Сеанс.ИмяПользователя} ИмяКомпьютера: %{Сеанс.ИмяКомпьютера}")
                        Сеанс.ЗавершитьСеанс("Технологический перезапуск сеансов")
                    иначе
                        Консоль.Записать("     Сеанс: %{Сеанс.ИмяПриложения} ИмяПользователя: %{Сеанс.ИмяПользователя} ИмяКомпьютера: %{Сеанс.ИмяКомпьютера}")
                    ;
                ;

                знч Соединения = ИнформационнаяБаза.ПолучитьСоединения()
                для Соединение из Соединения
                    если Соединение.ИмяПриложения == "1CV8C"
                        Консоль.Записать("    (-) Соединение: %{Соединение.ИмяПриложения} ИмяКомпьютера: %{Соединение.ИмяКомпьютера}")
                        Соединение.Отключить()
                    иначе
                        Консоль.Записать("    Соединение: %{Соединение.ИмяПриложения} ИмяКомпьютера: %{Соединение.ИмяКомпьютера}")

                    ;
                ;
            ;
        ;
    ;

    АдминистрированиеСервера.Закрыть()
;