Как написать дробное число прописью, например 19.737 (х=19.737)
Если использовать выражение Формат(х,"ЧП"), то напишется "двадцать",
а надо полностью. Собственно вопрос, как?

*.SPL смотри !

Посмотрел 1CV7.spl, что туда надо добавтиь, чтобы решить мою задачу. Файл ни разу не редактировался!

Формат(ИтСуммаСНДС, "ЧПДС") у меня так показывает !

Мне надо НЕ в денежном формате.

//******************************************************************************
// ЧислоПрописью()
//
// Параметры:
// ЗначЧисло - число, которое нужно представить прописью
//
// Возвращаемое значение:
// строка, число представленное прописью.
//
// Описание:
// Преобразует число в его представление пропись. В отличии от стандартной
// функции формат умеет преобразовывать дробные числа с точностью до 3-х
// знаков после запятой.
Функция ЧислоПрописью(ЗначЧисло) Экспорт
  
  Перем Возвр;
  Перем ЦелЧасть, ДробЧасть;
  Перем Дробная;
  Перем Окончание;
  Перем ПоследнееСлово;
  ЦелЧасть = Цел(ЗначЧисло);
  ДробЧасть = Окр(ЗначЧисло - ЦелЧасть, 3);
  
  Если ДробЧасть=Окр(ДробЧасть,0) Тогда
    ДробЧасть = 0;
    Дробная = "";
    
  ИначеЕсли ДробЧасть = Окр(ДробЧасть, 1) Тогда
    ДробЧасть = Окр(ДробЧасть, 1) * 10;
    Дробная = "десят";
    
  ИначеЕсли ДробЧасть = Окр(ДробЧасть, 2) Тогда
    ДробЧасть = Окр(ДробЧасть, 2) * 100;
    Дробная = "сот";
  Иначе
    ДробЧасть = ДробЧасть * 1000;
    Дробная = "тысячн";
  КонецЕсли;
  Возвр = "";
  Возвр = Возвр + ?(ПустоеЗначение(ЦелЧасть) = 1, "Ноль", СокрЛП(Формат(ЦелЧасть, "ЧП")));
  Если Дробная <> "" Тогда // есть дробная часть
    // теперь займемся окончанием последнего слова целой части
    ПоследнееСлово = "";
    Окончание = "";
    Пока (Возвр <> "") И (Возвр = СокрП(Возвр)) Цикл // последний символ в строке не пробел
      ПоследнееСлово = Прав(Возвр, 1) + ПоследнееСлово; // добавляем последнюю букву
      Возвр = Лев(Возвр, СтрДлина(Возвр) - 1); // отрезаем последнюю букву
    КонецЦикла;
    
    Если Врег(ПоследнееСлово) = "ОДИН" Тогда
      // первую букву слова оставляем
      ПоследнееСлово = Лев(ПоследнееСлово, 1) + "дна";
      Окончание = "ая";
    Иначе
      Если (Врег(ПоследнееСлово) = "ДВА") Тогда
        ПоследнееСлово = Лев(ПоследнееСлово, 1) + "ве";
      КонецЕсли;
      Окончание = "ых";
    КонецЕсли;
    Возвр = Возвр + ПоследнееСлово + " цел" + Окончание + " " + НРег(СокрЛП(Формат(ДробЧасть, "ЧП")));
    // теперь займемся окончанием последнего слова дробной части
    ПоследнееСлово = "";
    Окончание = "";
    
    Пока Возвр = СокрП(Возвр) Цикл // последний символ в строке не пробел
      ПоследнееСлово = Прав(Возвр, 1) + ПоследнееСлово; // добавляем последнюю букву
      Возвр = Лев(Возвр, СтрДлина(Возвр) - 1); // отрезаем последнюю букву
    КонецЦикла;
    
    Если Врег(ПоследнееСлово) = "ОДИН" Тогда
      // первую букву слова оставляем
      ПоследнееСлово = Лев(ПоследнееСлово, 1) + "дна";
      Окончание = "ая";
    Иначе
      Если (Врег(ПоследнееСлово) = "ДВА") Тогда
        ПоследнееСлово = Лев(ПоследнееСлово, 1) + "ве";
      КонецЕсли;
      
      Окончание = "ых";
    КонецЕсли;
    
    Возвр = Возвр + ПоследнееСлово + " " + Дробная + Окончание;
  КонецЕсли;
  Возврат Возвр;
  
КонецФункции // ЧислоПрописью()

Вот именно !

X=19.737;
Y=Цел(X);
Z=(X-Y)*1000;
Сообщить(Формат(Y,"ЧП")+" "+Формат(Z,"ЧП"));

Всем спасибо, работает.
Особый респект AVP!

Пожалуйста, тем более не мое :)))))