Доброго дня, коллеги!
есть запрос

ВЫБРАТЬ
    Номенклатура.Ссылка
ИЗ
    Справочник.Номенклатура КАК Номенклатура
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
        ПО Номенклатура.Ссылка = ЗначенияСвойствОбъектов.Объект
            И (ЗначенияСвойствОбъектов.Свойство = &Свойство)
ГДЕ
    НЕ Номенклатура.Ссылка В
                (ВЫБРАТЬ РАЗЛИЧНЫЕ
                    ПартииТоваровКомпанииОбороты.Номенклатура
                ИЗ
                    РегистрНакопления.ПартииТоваровКомпании.Обороты(&НачалоПериода, &КонецПериода, Год, ) КАК ПартииТоваровКомпанииОбороты)
    И ВЫБОР
            КОГДА ЗначенияСвойствОбъектов.Значение ЕСТЬ NULL
                ТОГДА ИСТИНА
            ИНАЧЕ ЗначенияСвойствОбъектов.Значение = &Неликвид
        КОНЕЦ

Не понимаю, почему он выполняется дольше чем этот:

ВЫБРАТЬ
    Номенклатура.Ссылка
ИЗ
    Справочник.Номенклатура КАК Номенклатура
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
        ПО Номенклатура.Ссылка = ЗначенияСвойствОбъектов.Объект
            И (ЗначенияСвойствОбъектов.Свойство = &Свойство)
ГДЕ
    НЕ Номенклатура.Ссылка В
                (ВЫБРАТЬ РАЗЛИЧНЫЕ
                    Номенклатура
                ИЗ
                    РегистрНакопления.ПартииТоваровКомпании Где Период Между &НачалоПериода и &КонецПериода)
    И ВЫБОР
            КОГДА ЗначенияСвойствОбъектов.Значение ЕСТЬ NULL
                ТОГДА ИСТИНА
            ИНАЧЕ ЗначенияСвойствОбъектов.Значение = &Неликвид
        КОНЕЦ

Ведь 1й использует итоги (да, они рассчитаны за этот период), что, собственно, должно влиять на производительность сего запроса, но этого не происходит.

ЗЫ: задача - получить неликвидные товары (по ним нет движений за указанный период)

(0) 1с вообще не рекомендует соединения с виртуальными таблицами. Создай временную и с ней соединяй

Почему за основную таблицу не взята РегистрНакопления.ПартииТоваровКомпании.Обороты?

*(2) извиняюсь "НЕ" не заметил

С временной таблицей оно, конечно, кошерней. Попробуй переделать на временную.

(1) результат запроса - 1кк записей, думаешь стоит в ВТ это хранить?))

У тебя ж Различные, или у тебя прям различных миллион?

Периодичность - год... неликвид по условию задачи - товар, по которому не было движений с год. Я беру обороты с периодичностью год. Итоги должны получиться мгновенно, но 1й выполнятся за 5с, а второй за 4с (данные обработки "Инструменты разработчика" 4.35).

(6) прямо миллион:")

(8) вот так "загажена" таблица номенклатуры)

(6) https://yadi.sk/i/g2z3czbq3Vf4JQ

(7) Раз уж используете ИР, тыкните там(на копии!) в результатах запроса внизу на последнюю вкладку "Запрос результата", там будет кнопка "Трасса"(план запроса для лентяев). он предложит настроить техножурнал и потом выдаст вам план запроса.

В первом запросе РАЗЛИЧНЫЕ - не нужно

возможно, есть смысл фильтровать по свойству - в параметрах вирт. таблицы

(7) А если "год" выкинуть из параметров?

(0) вообще не вижу смысла в соединении

условие на НЕ - плохое, можно попробовать полное соединение с регистром + ГДЕ регистр.номенклатура есть нулл. но без плана запроса разговор ниочем конечно

(11) попробую позже, что-то она висит)
(12) да, различные лишнее, по привычке добавил) в параметрах это будет точно лишнее
(13) ну, логично же, что будет хуже)
(14) а зря, ведь мне не нужны записи с уже установленным ПВХ "неликвид"

(15) да, тоже вариант, сейчас попробую. план будет чуть позже

(16) Для чего в запросе обращение к таблице Справочник.Номенклатура?

(18) чтобы получить номенклатуру БЕЗ ДВИЖЕНИЙ. Есть другой способ или я чего-то не знаю?!

(0) помимо всего вышеописанного, периодичность виртальной таблицы менять не пробовали? имхо, АВТО больше подходит.

(11) не умею настраивать ТЖ =)

(19) как-то так



ВЫБРАТЬ
    ЗначенияСвойствОбъектов.Объект
ИЗ
    РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
ГДЕ
    ЗначенияСвойствОбъектов.Объект ССЫЛКА Справочник.Номенклатура
    НЕ ЗначенияСвойствОбъектов.Объект В
                (ВЫБРАТЬ РАЗЛИЧНЫЕ
                    ПартииТоваровКомпанииОбороты.Номенклатура
                ИЗ
                    РегистрНакопления.ПартииТоваровКомпании.Обороты(&НачалоПериода, &КонецПериода, Год, ) КАК ПартииТоваровКомпанииОбороты)
    И (ЗначенияСвойствОбъектов.Значение ЕСТЬ NULL ИЛИ ЗначенияСвойствОбъектов.Значение = &Неликвид)

(22) + а, ну ещё условие на свойство впендюрить

(20) пробовал - разницы не вижу, хотя теоретически вряд ли оно больше подходит. кстати, ms sql 2014

(23) не у всей номенклатуры установлено свойство "неликвид", поэтому нужна основная таблица

(16) А ты попробуй.

(22) уверены, что в ЗначенияСвойствОбъектов есть все ссылки на номенклатуру?

Ну, ок. Таблица справочника нужна.
Тогда бы сделал через временные таблицы

(26) (24)

(27) их относительно мало. Свойства установлены примерно для 5% номенклатуры.

(29) попробуй наоборот пустить запросы. Есть вероятность, что sql во втором запросе использует кэш от первого запроса, поэтому 2й быстрее.

(15) разнозначно.. время одинаковое

ВЫБРАТЬ
    мНоменклатура.Ссылка
ИЗ
    Справочник.Номенклатура КАК мНоменклатура
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
        ПО мНоменклатура.Ссылка = ЗначенияСвойствОбъектов.Объект
            И (ЗначенияСвойствОбъектов.Свойство = &Свойство)
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ПартииТоваровКомпании.Обороты(&НачалоПериода, &КонецПериода, Авто, ) КАК ПартииТоваровКомпанииОбороты
        ПО мНоменклатура.Ссылка = ПартииТоваровКомпанииОбороты.Номенклатура
ГДЕ
    ПартииТоваровКомпанииОбороты.Номенклатура ЕСТЬ NULL
    И ВЫБОР
            КОГДА ЗначенияСвойствОбъектов.Значение ЕСТЬ NULL
                ТОГДА ИСТИНА
            ИНАЧЕ ЗначенияСвойствОбъектов.Значение = &Неликвид
        КОНЕЦ


В общем.. полез в Profiler

(31) пробовал - нет.

Попробуй вот эту строку убрать из соединений и впихнуть ее в другое место:
И (ЗначенияСвойствОбъектов.Свойство = &Свойство).

(33) только после перезагрузки компа. для чистоты эксперимента

ну и для справки, сколько такой запрос займет по времени?

ВЫБРАТЬ
ЗначенияСвойствОбъектов.Объект КАК НомЛиквид
ПОМЕСТИТЬ Фильтр1
ИЗ
РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
ГДЕ
ЗначенияСвойствОбъектов.Объект ССЫЛКА Справочник.Номенклатура И
ЗначенияСвойствОбъектов.Свойство = &Свойство И ЗначенияСвойствОбъектов.Значение <> &Неликвид
;
////
ВЫБРАТЬ РАЗЛИЧНЫЕ
ПартииТоваровКомпанииОбороты.Номенклатура КАК Номенклатура
ПОМЕСТИТЬ Фильтр2
ИЗ
РегистрНакопления.ПартииТоваровКомпании.Обороты(&НачалоПериода, &КонецПериода, Авто, НЕ Номенклатура В (Выбрать Фильтр1.НомЛиквид ИЗ Фильтр1 как Фильтр1))
ОБЪЕДИНИТЬ
Выбрать Фильтр1.НомЛиквид ИЗ Фильтр1 как Фильтр1
;
////
ВЫБРАТЬ
    Номенклатура.Ссылка
ИЗ
    Справочник.Номенклатура КАК Номенклатура
ГДЕ
НЕ Номенклатура.Ссылка В (Выбрать Фильтр2.Номенклатура из Фильтр2 как Фильтр2)

(36)Тогда соединение с временными таблицами и не Есть NULL

Пардон Есть NULL

(37) а, ну можно и так.

(36) пришлось "грохнуть", т.к. все повисло) збс запрос)))

(40) рад, что вам понравилось :)

Объясните кто-нибудь чем это условие

  ГДЕ
    ПартииТоваровКомпанииОбороты.Номенклатура ЕСТЬ NULL
    И ВЫБОР
        КОГДА ЗначенияСвойствОбъектов.Значение ЕСТЬ NULL
             ТОГДА ИСТИНА
        ИНАЧЕ ЗначенияСвойствОбъектов.Значение = &Неликвид
      КОНЕЦ

отличается от

  ГДЕ
    ПартииТоваровКомпанииОбороты.Номенклатура ЕСТЬ NULL
    И (ЗначенияСвойствОбъектов.Значение ЕСТЬ NULL
      ИЛИ ЗначенияСвойствОбъектов.Значение = &Неликвид)

РегистрНакопления.ПартииТоваровКомпании.Обороты(&НачалоПериода, &КонецПериода, Авто, НЕ Номенклатура В (Выбрать Фильтр1.НомЛиквид ИЗ Фильтр1 как Фильтр1))

фуфуфу - дрянька редкостная, не рекомендуется в параметрах виртуальных таблиц такие вещи писать.

ВЫБРАТЬ РАЗЛИЧНЫЕ
    Об.Номенклатура
ПОМЕСТИТЬ ТоварыСОборотами
ИЗ
    РегистрНакопления.ТоварыНаСкладах.Обороты КАК Об
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ЗначенияСвойствОбъектов.Объект
ПОМЕСТИТЬ НеликвидПоСвойству
ИЗ
    РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
ГДЕ
    ЗначенияСвойствОбъектов.Объект ССЫЛКА Справочник.Номенклатура
    И ЗначенияСвойствОбъектов.Значение = ИСТИНА
    И ЗначенияСвойствОбъектов.Свойство = &Неликвид
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    СпрНоменклатура.Ссылка
ИЗ
    Справочник.Номенклатура КАК СпрНоменклатура
        ЛЕВОЕ СОЕДИНЕНИЕ ТоварыСОборотами КАК ТоварыСОборотами
        ПО СпрНоменклатура.Ссылка = ТоварыСОборотами.Номенклатура
        ЛЕВОЕ СОЕДИНЕНИЕ НеликвидПоСвойству КАК НеликвидПоСвойству
        ПО СпрНоменклатура.Ссылка = НеликвидПоСвойству.Объект
ГДЕ
    ТоварыСОборотами.Номенклатура ЕСТЬ NULL
    И НЕ СпрНоменклатура.ЭтоГруппа
    И НеликвидПоСвойству.Объект ЕСТЬ NULL

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
    НеликвидПоСвойству.Объект
ИЗ
    НеликвидПоСвойству КАК НеликвидПоСвойству

(43) Какие "такие"? Это же обычные параметры - начало, конец, условие

+(44)сорян, под твой регистр:

ВЫБРАТЬ РАЗЛИЧНЫЕ
    Об.Номенклатура
ПОМЕСТИТЬ ТоварыСОборотами
ИЗ
    РегистрНакопления.ПартииТоваровКомпании.Обороты(&НачалоПериода, &КонецПериода, , ) КАК Об
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ЗначенияСвойствОбъектов.Объект
ПОМЕСТИТЬ НеликвидПоСвойству
ИЗ
    РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
ГДЕ
    ЗначенияСвойствОбъектов.Объект ССЫЛКА Справочник.Номенклатура
    И ЗначенияСвойствОбъектов.Значение = ИСТИНА
    И ЗначенияСвойствОбъектов.Свойство = &Неликвид
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ЗначенияСвойствОбъектов.Объект,
    ЗначенияСвойствОбъектов.Значение
ПОМЕСТИТЬ ЗначенияСвойства
ИЗ
    РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
ГДЕ
    ЗначенияСвойствОбъектов.Свойство = &Свойство
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    Товары.Ссылка,
    ЗначенияСвойства.Значение
ИЗ
    (ВЫБРАТЬ
        СпрНоменклатура.Ссылка КАК Ссылка
    ИЗ
        Справочник.Номенклатура КАК СпрНоменклатура
            ЛЕВОЕ СОЕДИНЕНИЕ ТоварыСОборотами КАК ТоварыСОборотами
            ПО СпрНоменклатура.Ссылка = ТоварыСОборотами.Номенклатура
            ЛЕВОЕ СОЕДИНЕНИЕ НеликвидПоСвойству КАК НеликвидПоСвойству
            ПО СпрНоменклатура.Ссылка = НеликвидПоСвойству.Объект
    ГДЕ
        ТоварыСОборотами.Номенклатура ЕСТЬ NULL
        И НЕ СпрНоменклатура.ЭтоГруппа
        И НеликвидПоСвойству.Объект ЕСТЬ NULL
    
    ОБЪЕДИНИТЬ ВСЕ
    
    ВЫБРАТЬ
        НеликвидПоСвойству.Объект
    ИЗ
        НеликвидПоСвойству КАК НеликвидПоСвойству) КАК Товары
        ЛЕВОЕ СОЕДИНЕНИЕ ЗначенияСвойства КАК ЗначенияСвойства
        ПО Товары.Ссылка = ЗначенияСвойства.Объект

(20) За таб. оборотов и "АВТО" - куля в лоб, выбирай из реальной таблицы!
"НЕ Номенклатура В (" - по пальцам дать.
Господа, достаньте консоль с планом запроса и посмотрите во что эти запросы преобразуются

(32) Убери ты этот ВЫБОР из ГДЕ. Сделай как в (22)

а ещеб я затестил:

ВЫБРАТЬ РАЗЛИЧНЫЕ
    Об.Номенклатура
ИЗ
    РегистрНакопления.ПартииТоваровКомпании.Обороты(&НачалоПериода, &КонецПериода, , ) КАК Об

И

ВЫБРАТЬ РАЗЛИЧНЫЕ
    Об.Номенклатура
ИЗ
    РегистрНакопления.ПартииТоваровКомпании КАК Об
ГДЕ
   об.Период МЕЖДУ &НачалоПериода И &КонецПериода

+(49) Кстати в первом варианте "РАЗЛИЧНЫЕ" - не нужны, оно будет замедлять

(50) в данном случае да

Т.е. нет смысла в получении оборотов, рассчитанных в виртуальной таблице, если не просить детализацю расчёта по периоду внутри интересующего периода оборота? Чё за дичь?

Правильнее заставить систему посчитать сумму по группировке из измерений?

(52) Зависит от периодичности.

(54) Да что зависит-то? Если цель виртуальной таблицы - представить предподготовленные отчётные данные.
Периодичность - месяц, запрос за год, в месяц движений 273000. Предлагаете 12 * 273000 строк заново посчитать? И это будет быстрее, чем система сложит 12х цифр?

(52) Детализация АВТО, как думаешь во что разворачивает твой запрос по регистру оборотов платформа?

Открой чистую СКД, сделай выборку по регистру оборотов, поставь периодичность АВТО, посмотри поля которые можно выбрать и поставь периодичность МЕСЯЦ и так же посмотри что там можно выбрать

А шлифануть: Возми консоль с планом запроса, сначала посмотри "гибридный запрос", который платформа генерит с периодичностью АВТО, а затем с периодичностью МЕСЯЦ.

+(56) а если ее приаттачить левым соединением к чему-нить.., тут туши свет

(55) Оно все равно складывает, неявно для Вас

(55) Периодичность должна быть больше месяца, тогда это имеет смысл...

(15) запрос с оборотами
https://yadi.sk/i/PUi-dNe73VfRVt
Запрос с физ таблицей
https://yadi.sk/i/PUi-dNe73VfRVt

Параллелизм...

"Если цель виртуальной таблицы - представить предподготовленные отчётные данные." - цель виртуальной таблицы - облегчить жизнь 1с-программистам

(60) https://yadi.sk/i/ZF5Jbs2j3VfRiY

параллельное выполнение даёт около 20% выигрыша)

Запрос с физ таблицей выполнился в 10 раз дольше - это выигрыш в 20% ?
Срочно - в спортлото! Не, обыгрывать вулкан через телеграмм!

Чувак, ты сейчас только что оказался умнее половины тех, кто тебе давал советы :)

(63) неужели

Никто не говорит что нельзя использовать вирт Таблицу оборотов, можно, но нужно знать когда это может привести к проблемам

Тут еще вопрос методический, зависящий от того как построена работа этого регистра. Может быть такое, что возвраты отражаются путём формирования записей с минусом (продажа - расход с "плюсом", а возврат - расход с "минусом"). Тогда в итоговых таблицах оборотов такой номенклатуры может не быть (если продали 10, а потом вернули -10, то 10-10=0).
В таких случаях корректнее обращаться к таблице первичных движений.

В любом случае, если даже брать таблицу итогов, то указываться периодичность (хоть "год", хоть "авто") не нужно.

Странная эта штука, параллелизм, он то включается, то нет. Вот сейчас и для оборотов сработал. Время выполнения запроса странное, то 4 секунды, то 5, то 9.

В общем, возьму ка я физическую таблицу... ну их нафиг эти дурные итоги.

(70) только попадай в индексы)

Что п второму пункту: "НЕ Номенклатура В (" ?
Понятно одно - левое соединение с отбором по NULL. Чем оно не устраивает виртуальную таблицу, которая сама напрашивается на фильтр? Допустим, НЕ В (30000 значений из 100 тыщ всего)

(71) Тут везде index seek.
(72) не понял вопроса

(60) ппц, я скрины не те выложил, ахахаха

(74) Да пофиг уже - тебе же уже написали, что ты оказался умнее доброй половины))

(68) спасибо за совет, уточню у постановщика задачи... может вообще все не так)

(72) Если это мне вопрос, то использование НЕ в условии ГДЕ, может быть проблема связанная с выбором оптимизатором не верного решения. Если ничего путаю

+(77) Нет, не путаю, вот ссылка:
http://www.sql-server-performance.com/2017/t-sql-where/

+(78) А именно:
Non-sargable search arguments in the WHERE clause, such as “IS NULL”, “<>”, “!=”, “!>”, “!<“, “NOT”, “NOT EXISTS”, “NOT IN”, “NOT LIKE”, and “LIKE ‘%500′” generally prevents (but not always) the query optimizer from using a useful index to perform a search. In addition, expressions that include a function on a column, expressions that have the same column on both sides of the operator, or comparisons against a column (not a constant), are not sargable.

(77) нет, он умный, это мы тупые)

(80) умные иногда тоже тупят)

(79) Так тут про "Non-sargable", а у нас в примере "sargable".

Вот тут sargable(72)?
Не вижу.

Если еще нужно, для sargable, то вот:
If you currently have a query that uses NOT IN, which offers poor performance because the SQL Server optimizer has to use a scan to perform this activity, instead try to use one of the following options, all of which offer better performance:

    Use EXISTS or NOT EXISTS.
    Use IN.
    Perform a LEFT OUTER JOIN and check for a NULL condition

(82) Рекомендую ознакомится со ВСЕЙ статьей, думаю что все вопросы отпадут

(84) в (43) порекомендуй, там не в курсе - гадости мерещатся.

Оказалось, что нужна номенклатура с остатком, а не из физ. таблицы :)

(86), извини...

(84) А конструкция "Use EXISTS or NOT EXISTS." - как в 1С выглядит?

(87) не встречался

И, получается, что не исключать из выборки 30% ненужного выгодно, а соединять с 70% нужного. Да, про то я забыл совсем, про ограничение такое в эскуэль

(86) Так а вопрос какой-то актуальным остался?
Просто, даже из (0) - разница 4 и 5 секунд - ниочём. Вот 35 секунд 5 секунд - это показатель. И такое реально бывает, индексировать временные таблицы приходится, например

(89)
"что не исключать из выборки 30% ненужного выгодно, а соединять с 70% нужного" - ну почему же не исключать, исключать ненужное крайне желательно. Все становится очевидно(или нет), когда посмотришь план выполнения запроса.

(91) Эх, знал бы я, как смотреть план... Да у меня и базы такой нет, чтобы увидеть разницу. Нет запроса, выполняющегося дольше 5 секунд

(92) Консоль запросов на ИТС, подойдут любые запросы по регистру оборотов

(87) эмулируется как ГДЕ 1 В (ВЫБРАТЬ Первые 1 1 ИЗ...)

(90) Для меня разница в секунду существенна) Поэтому я и запили тему. Кстати, планы запросов оказались почти идентичны, оба распралаллеливаются, но есть тонкие отличия в логике, думаю, даже нет смысла спрашивать их тут =)

Т.к. постановка задачи была изменена, то для решения достаточно виртуальной "ОстаткиИОбороты".

ВЫБРАТЬ
    ЗначенияСвойствОбъектов.Объект КАК Номенклатура
ПОМЕСТИТЬ Неликвиды
ИЗ
    РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
ГДЕ
    ЗначенияСвойствОбъектов.Свойство = &Свойство
    И ЗначенияСвойствОбъектов.Значение = &Неликвид
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ПартииТоваровКомпанииОстаткиИОбороты.Номенклатура,
    ПартииТоваровКомпанииОстаткиИОбороты.КоличествоКонечныйОстаток
ИЗ
    РегистрНакопления.ПартииТоваровКомпании.ОстаткиИОбороты(&НачалоПериода, , , , ) КАК ПартииТоваровКомпанииОстаткиИОбороты
ГДЕ
    ПартииТоваровКомпанииОстаткиИОбороты.КоличествоРасход = 0
    И ПартииТоваровКомпанииОстаткиИОбороты.КоличествоПриход = 0
    И НЕ ПартииТоваровКомпанииОстаткиИОбороты.Номенклатура В
                (ВЫБРАТЬ
                    Неликвиды.Номенклатура
                ИЗ
                    Неликвиды)

Проверил - результат вроде правильный, и выполняется около секунды.

(95) Наверное, лучше соединением фильтровать/исключать, но точно не в параметрах ВТ :)

Исправим, а то закидают помидорками:)
ВЫБРАТЬ
    ЗначенияСвойствОбъектов.Объект КАК Номенклатура
ПОМЕСТИТЬ Неликвиды
ИЗ
    РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
ГДЕ
    ЗначенияСвойствОбъектов.Свойство = &Свойство
    И ЗначенияСвойствОбъектов.Значение = &Неликвид
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ПартииТоваровКомпанииОстаткиИОбороты.Номенклатура КАК Номенклатура,
    ПартииТоваровКомпанииОстаткиИОбороты.КоличествоКонечныйОстаток
ИЗ
    РегистрНакопления.ПартииТоваровКомпании.ОстаткиИОбороты(&НачалоПериода, , , , ) КАК ПартииТоваровКомпанииОстаткиИОбороты
        ЛЕВОЕ СОЕДИНЕНИЕ Неликвиды КАК Неликвиды
        ПО ПартииТоваровКомпанииОстаткиИОбороты.Номенклатура = Неликвиды.Номенклатура
ГДЕ
    ПартииТоваровКомпанииОстаткиИОбороты.КоличествоРасход = 0
    И ПартииТоваровКомпанииОстаткиИОбороты.КоличествоПриход = 0
    И Неликвиды.Номенклатура ЕСТЬ NULL


(97) Будет тормозить
Какой тип у "ЗначенияСвойствОбъектов.Объект"?
А соединение с составным типом к чему может привести?

(97) Использование "РегистрНакопления.ПартииТоваровКомпании.ОстаткиИОбороты" оправдано?

+(99) Используй ВЫРАЗИТЬ(ЗначенияСвойств.Объект КАК Справочник.Номенклатура)

(98) (100) вы не понимаете о чем пишете
соединение с составным типом тормозит когда из него получается реквизит через точку. а ЗначенияСвойствОбъектов.Объект КАК Номенклатура
и так ссылочный тип номенклатура, не нужно ничего выражать

(101) Откуда Вам знать что я понимаю, а что нет?  "Зарапартовался"

Выполняется дольше, по тому что ты в первом запросе используешь виртуальную таблицу, которая выгребает в том числе и остатки, а во втором случае физическую таблицу. Так как номенклатура содержится в индексе, то чтение всей таблицы не происходит, а только индекса скорее всего. А вообще правильнее на мой взгляд писать запрос таким образом, но и он скорее всего не оптимален но достаточен:

ВЫБРАТЬ
    спрНоменклатура.Ссылка
ИЗ
    Справочник.Номенклатура КАК спрНоменклатура

    ЛЕВОЕ СОЕДИНЕНИЕ ( ВЫБРАТЬ РАЗЛИЧНЫЕ
        Номенклатура
    ИЗ
        РегистрНакопления.ПартииТоваровКомпании
    ГДЕ
        Период МЕЖДУ &НачалоПериода И &КонецПериода

    ) КАК тзФильтр
        ПО спрНоменклатура.Ссылка = тзФильтр.Номенклатура

    ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЗначенияСвойствОбъектов КАК тзЗначения
        ПО спрНоменклатура.Ссылка = тзЗначения.Объект
         И тзЗначения.Свойство = &Свойство
ГДЕ
    тзФильтр.Номенклатура ЕСТЬ NULL
    И ( тзЗначения.Значение ЕСТЬ NULL Или тзЗначения.Значение = &Неликвид )

(0)
(7) 1й выполнятся за 5с, а второй за 4с

Тема не о чем. Весь сыр бор из 1 секунды!

Допустим твой час стоит 1000 рублей.
Ты на форуме провисел 8 часов, затратил на оптимизацию 8000 рублей. Оптимизацию в 1 секунду?
Директор бы увидел, уволил.

(104) На разном железе с разным периодом может быть разница не в секунду... А так нужно сразу стараться писать правильно и всё не будет никаких 2-х вариантов.

(103) Соединение с подзапросом?

(105) Если отчет используют десятки или сотни раз в день, то его стоит оптимизировать.

Если его используют 1 раз в неделю, а такие отчеты как в (0) используют не часто, да пусть он хоть 30 секунд выполняется.

(107) Это да. Но мозг прокачивать всё же нужно, так что пусть тренеруется