Почему не правильно работает функция Выразить( .... как строка(3)) в запросе для числового значения
Выдает пустую строку
Если поставить Представить() то получаю значение, но негде его в группировке использовать не могу и не могу взять из него часть строки

Как получить из числового параметра в запросе строку нужной длинны, так что бы его дальше можно было использовать?

В запросе - никак.

Никак.

(0) В принципе - можно, но это будет изврат редкостный.
Используешь остаток от деления и ПОДСТРОКА().

Хорошо подумай, зачем тебе именно так. Соглашусь с мнением большинства, что подобного рода требования - это ошибка проектирования. Попробуй найти другой вариант, учитывая, что первый вариант не реализуем - он точно есть.

(4) сам запрос довольно большой и если не удастся получить этот кусок строки (его дальше надо сравнивать с другими строками и потом объединять, если не удастся придется переписывать весь алгоритм в модуль)

(0) единственный метод я сам вижу это выгрузить все в таблицу в программе обработать и потом в запрос по новой забросить

(5) Иногда проще переписать кусок запроса, чем вставлять костыли.

Заполнить всевозможные числовые значения (если они конечны) в ТЗ (колонка1,колонка2 - 3,14,"3,14") и засунуть в запрос, ну и левым к ТЗ

А для чего нужно число в строку, если не секрет?

Для трехзначных чисел будет работать что-то типа:


ВЫБРАТЬ ПОДСТРОКА("0123456789",563/100+1,1)+
ПОДСТРОКА("0123456789",(563-(Выразить(563/100 - 0.5 как ЧИСЛО(3,0))*100)-563+(Выразить(563/10 - 0.5 как ЧИСЛО(3,0))*10))/10+1,1)+
ПОДСТРОКА("0123456789",563-(Выразить(563/10 - 0.5 как ЧИСЛО(3,0))*10)+1,1)


а что такое Представить() в языке запросов?

+11 не нашел в списке функций

(11)  Ты даже не Представляешь()

Думаю ТС ошибся с Представление()

(13) я уж подумал - может это 8.3.7 на лыжах дошла )

(0) Если очень хочется, то можно!
Вот статья: Выразить число как строку и дату как строку в запросе http://catalog.mista.ru/public/331805/ .
Для трехзначного числа выражение будет не слишком сложным:
ПОДСТРОКА("0123456789", СЕКУНДА(ДОБАВИТЬКДАТЕ(ДАТАВРЕМЯ(1, 1, 1), СЕКУНДА, &Число * 0.06)) / 6 + 1, 1)
    + ПОДСТРОКА("0123456789", СЕКУНДА(ДОБАВИТЬКДАТЕ(ДАТАВРЕМЯ(1, 1, 1), СЕКУНДА, &Число * 0.6)) / 6 + 1, 1)
    + ПОДСТРОКА("0123456789", СЕКУНДА(ДОБАВИТЬКДАТЕ(ДАТАВРЕМЯ(1, 1, 1), СЕКУНДА, &Число * 6)) / 6 + 1, 1)

(15) число может быть трехзначным, а этот вариант работает только для числа

(16)+ только для одной цифры

(17) Для любого трехзначного числа работает.

Все реализовал

ВЫБРАТЬ
    ВложенныйЗапрос.Объект,
    МАКСИМУМ(ВложенныйЗапрос.Значение) КАК Значение
ИЗ
    (ВЫБРАТЬ
        ВложенныйЗапрос1.Объект КАК Объект,
        ПОДСТРОКА("0123456789", ВложенныйЗапрос1.ПерваяЦифра + 1, 1) + ПОДСТРОКА("0123456789", ВложенныйЗапрос1.ВтораяЦифра + 1, 1) + ПОДСТРОКА("0123456789", ВложенныйЗапрос1.ТретьяЦифра + 1, 1) КАК Значение
    ИЗ
        (ВЫБРАТЬ
            ВложенныйЗапрос.Объект КАК Объект,
            ВЫРАЗИТЬ(ВложенныйЗапрос.Значение / 100 КАК ЧИСЛО(1, 0)) КАК ПерваяЦифра,
            (ВЫРАЗИТЬ(ВложенныйЗапрос.Значение / 10 КАК ЧИСЛО(2, 0))) - (ВЫРАЗИТЬ(ВложенныйЗапрос.Значение / 100 КАК ЧИСЛО(1, 0))) * 10 КАК ВтораяЦифра,
            ВложенныйЗапрос.Значение - (ВЫРАЗИТЬ(ВложенныйЗапрос.Значение / 10 КАК ЧИСЛО(2, 0))) * 10 КАК ТретьяЦифра,
            ВложенныйЗапрос.Значение КАК Значение
        ИЗ
            (ВЫБРАТЬ
                ЗначенияСвойствОбъектов.Объект КАК Объект,
                ВЫРАЗИТЬ(ЗначенияСвойствОбъектов.Значение КАК ЧИСЛО(3, 0)) КАК Значение
            ИЗ
                РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
            ГДЕ
                ЗначенияСвойствОбъектов.Свойство.Код = "Оф086      ") КАК ВложенныйЗапрос) КАК ВложенныйЗапрос1) КАК ВложенныйЗапрос

СГРУППИРОВАТЬ ПО
    ВложенныйЗапрос.Объект

(19) У тебя остаток от деления считается неправильно. Ты не учел, что ВЫРАЗИТЬ() округляет по правилам округления, а не отбрасывает дробную часть.

+(20) Вариант из (15) лучше.

(20) в системе настраивается как округлять

(22) Каким образом?

(23) поправил запрос

ВЫБРАТЬ
    ВложенныйЗапрос.Объект,
    МАКСИМУМ(ВложенныйЗапрос.Значение) КАК Значение
ИЗ
    (ВЫБРАТЬ
        ВложенныйЗапрос1.Объект КАК Объект,
        ПОДСТРОКА("0123456789", ВложенныйЗапрос1.ПерваяЦифра + 1, 1) + ПОДСТРОКА("0123456789", ВложенныйЗапрос1.ВтораяЦифра + 1, 1) + ПОДСТРОКА("0123456789", ВложенныйЗапрос1.ТретьяЦифра + 1, 1) КАК Значение
    ИЗ
        (ВЫБРАТЬ
            ВложенныйЗапрос.Объект КАК Объект,
            ВЫРАЗИТЬ(ВложенныйЗапрос.Значение / 100 - 0.5 КАК ЧИСЛО(1, 0)) КАК ПерваяЦифра,
            (ВЫРАЗИТЬ(ВложенныйЗапрос.Значение / 10 - 0.5 КАК ЧИСЛО(2, 0))) - (ВЫРАЗИТЬ(ВложенныйЗапрос.Значение / 100 - 0.5 КАК ЧИСЛО(1, 0))) * 10 КАК ВтораяЦифра,
            ВложенныйЗапрос.Значение - (ВЫРАЗИТЬ(ВложенныйЗапрос.Значение / 10 - 0.5 КАК ЧИСЛО(2, 0))) * 10 КАК ТретьяЦифра,
            ВложенныйЗапрос.Значение КАК Значение
        ИЗ
            (ВЫБРАТЬ
                ЗначенияСвойствОбъектов.Объект КАК Объект,
                ВЫРАЗИТЬ(ЗначенияСвойствОбъектов.Значение КАК ЧИСЛО(3, 0)) КАК Значение
            ИЗ
                РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
            ГДЕ
                ЗначенияСвойствОбъектов.Свойство.Код = "Оф086      ") КАК ВложенныйЗапрос) КАК ВложенныйЗапрос1) КАК ВложенныйЗапрос

СГРУППИРОВАТЬ ПО
    ВложенныйЗапрос.Объект

(24) Должно работать.