Набросал 2 примера использования ВЫРАЗИТЬ (по итогам поиска по форуму с проблемой 256 таблиц). Какой правильнее?
1)
ВЫБРАТЬ
    ПартииТоваровНаСкладахОбороты.Регистратор,
    ВЫБОР
        КОГДА ВЫРАЗИТЬ(ПартииТоваровНаСкладахОбороты.Регистратор КАК Документ.ПоступлениеТоваровУслуг) ССЫЛКА Документ.ПоступлениеТоваровУслуг
            ТОГДА ВЫРАЗИТЬ(ПартииТоваровНаСкладахОбороты.Регистратор КАК Документ.ПоступлениеТоваровУслуг).Контрагент
        КОГДА ВЫРАЗИТЬ(ПартииТоваровНаСкладахОбороты.Регистратор КАК Документ.РеализацияТоваровУслуг) ССЫЛКА Документ.РеализацияТоваровУслуг
            ТОГДА ВЫРАЗИТЬ(ПартииТоваровНаСкладахОбороты.Регистратор КАК Документ.РеализацияТоваровУслуг).Контрагент
        ИНАЧЕ НЕОПРЕДЕЛЕНО
    КОНЕЦ КАК Поле1,
    ПартииТоваровНаСкладахОбороты.КоличествоОборот
ИЗ
    РегистрНакопления.ПартииТоваровНаСкладах.Обороты(&Дата1, &Дата2, Регистратор, ) КАК ПартииТоваровНаСкладахОбороты

2)
ВЫБРАТЬ
    ПартииТоваровНаСкладахОбороты.Регистратор,
    ВЫБОР
        КОГДА ПартииТоваровНаСкладахОбороты.Регистратор ССЫЛКА Документ.ПоступлениеТоваровУслуг
            ТОГДА ВЫРАЗИТЬ(ПартииТоваровНаСкладахОбороты.Регистратор КАК Документ.ПоступлениеТоваровУслуг).Контрагент
        КОГДА ПартииТоваровНаСкладахОбороты.Регистратор ССЫЛКА Документ.РеализацияТоваровУслуг
            ТОГДА ВЫРАЗИТЬ(ПартииТоваровНаСкладахОбороты.Регистратор КАК Документ.РеализацияТоваровУслуг).Контрагент
        ИНАЧЕ НЕОПРЕДЕЛЕНО
    КОНЕЦ КАК Поле1,
    ПартииТоваровНаСкладахОбороты.КоличествоОборот
ИЗ
    РегистрНакопления.ПартииТоваровНаСкладах.Обороты(&Дата1, &Дата2, Регистратор, ) КАК ПартииТоваровНаСкладахОбороты

эм... а скуль обновить - никак?

зы в регистраторах ПартииТоваровНаСкладах 256 таблиц разве наберется?

Первый упадёт, второй взлетит

(0) И шо таки значит пгавильнее?

(2) Это просто для примера, реальный запрос другой. В реальном запросе много мест, где надо оптимизировать, поэтому мне желательно знать какой вариант, чтобы не переделывать.
(3) Оба вышеуказанных запроса работают.

(5) тут только вскрытие покажет - смотреть что на скуль приходит

если они отличаются только Выразить в куске "когда" то вариант 2 правильнее. первый вариант возвращает лажу

(5) Уверен?
У меня на подобном запросе вылезает несоответствие типов

ВЫБРАТЬ ПЕРВЫЕ 1
    ВЫБОР КОГДА ВЫРАЗИТЬ (ОтпускаОрганизаций.Ссылка  КАК Документ.Встречи) ССЫЛКА Документ.Встречи ТОГДА 1
    ИНАЧЕ 2 КОНЕЦ КАК А
ИЗ
    Документ.ОтпускаОрганизаций  КАК ОтпускаОрганизаций


Точнее, "Несовместимые типы ВЫРАЗИТЬ ..."
А такой работает

ВЫБРАТЬ ПЕРВЫЕ 1
    ВЫБОР КОГДА ВЫРАЗИТЬ (Встречи.Ссылка  КАК Документ.Встречи) ССЫЛКА Документ.Встречи ТОГДА 1
    ИНАЧЕ 2 КОНЕЦ КАК А
ИЗ
    Документ.Встречи  КАК Встречи


(8) работать не будет - это и так понятно

Вот ещё:

http://zapros-1c-8.ru/interest/11-express

>Регистратор у регистров часто имеет составной тип, чтобы преобразовать его к одиночному типу используйте конструкцию ВЫРАЗИТЬ правда если на этапе выборки вы попытаетесь преобразовать документ реализацию в документ поступление, то запрос обязательно вылетит с ошибкой, поэтому перед преобразованием следует проверить тип ссылки.

Да и выражать одно поле по несколько раз не очень оптимально.

Поставил себе SQL EXPRESS, сделал в тестовой базе 300 видов документов, у одного вида реквизит контрагент. Сделал регистр сведений с измерением типа документ.ссылка. И запрос к этому измерению вида РегистрСведений.Документ.Контрагент нормально отрабатывает, вот печаль.

(13) здиш

> (0) Какой правильнее?
Правильнее так:

ВЫБРАТЬ
    Партии.Регистратор,
    ЕСТЬNULL(Поступления.Контрагент, ЕСТЬNULL(Реализации.Контрагент, НЕОПРЕДЕЛЕНО)) КАК Контрагент,
    Партии.КоличествоОборот
ИЗ
    РегистрНакопления.ПартииТоваровНаСкладах.Обороты(&Дата1, &Дата2, Регистратор, ) КАК Партии
    ЛЕВОЕ СОЕДИНЕНИЕ Документ.ПоступлениеТоваровУслуг КАК Поступления
        ПО Поступления.Ссылка = Партии.Регистратор
    ЛЕВОЕ СОЕДИНЕНИЕ Документ.РеализацияТоваровУслуг КАК Реализации
        ПО Реализации.Ссылка = Партии.Регистратор