Как получить список всех родителей элемента справочника, начиная с самого верхнего?

Ниже рабочий код, но мне кажется, что есть более простой способ.

Номенклатура = Справочники.Номенклатура.НайтиПоКоду("0004324234");
Список = Новый СписокЗначений;
Пока 1 = 1 Цикл
       
   Если ЗначениеЗаполнено(Номенклатура.Родитель) Тогда
       Список.Добавить(Номенклатура.Родитель);
       Номенклатура = Номенклатура.Родитель;
   Иначе
       Прервать;
   КонецЕсли;
       
КонецЦикла;    
   
Индекс = Список.Количество() - 1;
Пока 1 = 1 Цикл
   Если Индекс >= 0 Тогда
       Сообщить(Список.Получить(Индекс));
       Индекс = Индекс - 1;
   Иначе
       Прервать;
   КонецЕсли;
КонецЦикла;

забавные циклы

(0) запрос, только иерархия...

Простые примеры разработки. стр. 87...

Номенклатура = Справочники.Номенклатура.НайтиПоКоду("0004324234");
Список = Новый СписокЗначений;
Родитель = Номенклатура.Родитель;
Пока ЗначениеЗаполнено(Родитель) Цикл
  Сообщить(Родитель);
  Список.Добавить(Родитель);
  Родитель = Родитель.Родитель;
КонецЦикла;

(3) Книги у меня такой нет, но есть HTML вариант, какой заголовок на стр. 87?

Вот вариант через запрос, что-то ещё можно упростить?

Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
|    Номенклатура.Ссылка КАК Ссылка
|ИЗ
|    Справочник.Номенклатура КАК Номенклатура
|ГДЕ
|    Номенклатура.Код = &Код
|ИТОГИ ПО
|    Ссылка ТОЛЬКО ИЕРАРХИЯ";
   
Запрос.УстановитьПараметр("Код", "0004324234");
Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
   Если Выборка.Ссылка.ЭтоГруппа Тогда
       Сообщить(Выборка.Ссылка);
   КонецЕсли;
КонецЦикла;

Номенклатура.Код = &Код
это пять

Если Выборка.Ссылка.ЭтоГруппа Тогда

ну и это не надо. У тебя и так ТОЛЬКО ИЕРАРХИЯ

(8) Если убрать условие, то выводит и сам элемент...

Строка кода "Если Выборка.Ссылка.ЭтоГруппа" - порождает обращение к базе для получения объекта (всех его реквизитов). Это ни есть хорошо.

(10) А как тогда в запросе исключить сам элемент?

//-------
Процедура СоставитьСписокРодителей(Ном,СпРод)
  Если ЗначениеЗаполнено(Ном.Родитель) Тогда
      СпРод.Добавить(Ном.Родитель);
      ВернутьСписокРодителей(Ном.Родитель,СпРод)
  КонецЕсли;
 
КонецПроцедуры


//-------

 спРод=Новый СписокЗначений;
 ВернутьСписокРодителей(Номенклатура,СпРод);

ВернутьСписокРодителей в Если = СоставитьСписокРодителей

+и после тоже:)

сначала хотел функцией:)

Рэйв, извини конечно, но что-то ты намудрил... полный код выложи.

(16)Чего мудрого? Обычная рекурсия.

Вариант а):

ТекНоменклатура = Справочники.Номенклатура.НайтиПоКоду("0004324234");

Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
|    Номенклатура.Ссылка КАК Ссылка
|ИЗ
|    Справочник.Номенклатура КАК Номенклатура
|ГДЕ
|    Номенклатура = &Элемент
|ИТОГИ ПО
|    Ссылка ТОЛЬКО ИЕРАРХИЯ";
   
Запрос.УстановитьПараметр("Элемент", ТекНоменклатура);
Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
   Если Выборка.Ссылка <> ТекНоменклатура Тогда
       Сообщить(Выборка.Ссылка);
   КонецЕсли;
КонецЦикла;

(17) не читаемо (12) + (13) + (14) + (15) = "полный код выложи" :)

Вариант б):

ТекКод = "0004324234";

Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
|    Номенклатура.Ссылка КАК Ссылка,
|    Номенклатура.Код КАК Код
|ИЗ
|    Справочник.Номенклатура КАК Номенклатура
|ГДЕ
|    Номенклатура.Код = &Код
|ИТОГИ ПО
|    Ссылка ТОЛЬКО ИЕРАРХИЯ";
   
Запрос.УстановитьПараметр("Код", ТекКод);
Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
   Если Выборка.Код <> ТекКод Тогда
       Сообщить(Выборка.Ссылка);
   КонецЕсли;
КонецЦикла;

(18) Спс, похоже это конечный вариант.

(0)А можно узнать практичческое применение? Для чего вам это надо?

(19)Ну вот так гдето :))

//-------
Процедура СоставитьСписокРодителей(Ном,СпРод)
  Если ЗначениеЗаполнено(Ном.Родитель) Тогда
      СпРод.Добавить(Ном.Родитель);
      СоставитьСписокРодителей(Ном.Родитель,СпРод)
  КонецЕсли;
 
КонецПроцедуры


//------- гдето в коде

 спРод=Новый СписокЗначений;
 СоставитьСписокРодителей(Номенклатура,спРод);
 Для каждого Эл из спРод Цикл
    Сообщить(Эл.Значение);
 КонецЦикла;

(23) Спасибо :)

(22) Делается выгрузка номенкалтуры, где необходимо указать всех родителей по порядку.

(22) Для веб-сайта.

Не особо радуйся. Рекурсия в платформе реализована так, что скорость исполнения падает на порядок :(

что-то не вижу ПолучитьПолныйКод()? али не кошерно?

(27) Рекурсией пользоваться в этом случае не собираюсь. Конечный вариант использование (18)

(28) А это тут зачем?

Получить полный код элемента и в цикле, перебирая все коды, получить всех родителей через НайтиПоКоду()... как бы это сказать... это уже извращение :)

Для прикола ради :)

ВсеКоды = СтрЗаменить(Справочники.Номенклатура.НайтиПоКоду("0004324234").ПолныйКод(),"/",Символы.ПС);
Для Индекс = 1 По СтрЧислоСтрок(ВсеКоды) Цикл
  Сообщить(Справочники.Номенклатура.НайтиПоКоду(СтрПолучитьСтроку(ВсеКоды,Индекс));
КонецЦикла;

(32) Ыыы :( скобки не хватает в конце строки "Сообщить..."