Подскажите как программно установить текущую строку. Я понимаю что нужно юзать "ТекущаяСтрока", но ей присваивается не номер строки, а индекс. Тогда как получить индекс следующей строки.

Стр = Объект.Товары.Добавить();
Элементы.Товары.ТекущаяСтрока = Стр.ПолучитьИдентификатор();

Строки уже сформированы (выгружены запросом). Далее нужно по ним перемещять курсор.

Это как? чтоб курсор шарился по форме самостоятельно?

Нет. Есть две кнопки. Предыдущая строка. Следующая строка.

Механизм удаления текущей строки (под свой случай думаю сам доведешь):

   ИдентификаторСтроки = Элементы.Погрузки.ТекущаяСтрока;
   Если ИдентификаторСтроки <> Неопределено Тогда
       ЭлементКоллекции = Объект.Погрузки.НайтиПоИдентификатору(ИдентификаторСтроки);
       ИндексЭлементаКоллекции = Объект.Погрузки.Индекс(ЭлементКоллекции);
       Объект.Погрузки.Удалить(ИндексЭлементаКоллекции);
   КонецЕсли;


ИндексТекСтроки = ТЗСвязаннаяСТаблПолем.Индекс(Элементы.Погрузки.ТекущаяСтрока);


Как получить индекс текущей строки я понимаю, а как получить индекс следующей строки (она не активна).

в смысле? 1 не прибавить?

Переход на след. строку:

Элементы.Погрузки.ТекущаяСтрока = ТЗсвязаннаяСТаблПолем[ИндексТекСтроки + 1]
[/С]
ну еще довесить контроль на последнюю и первую строку.


Элементы.Погрузки.ТекущаяСтрока = ТЗсвязаннаяСТаблПолем[ИндексТекСтроки + 1]


Таак. Чет я совсем похоже заблудился.
"ТЗСвязаннаяСТаблПолем.Индекс(Элементы.Погрузки.ТекущаяСтрока)"
В Индекс(...) Нужно передать строку, для того чтоб получить индекс.
"Элементы.Погрузки.ТекущаяСтрока" - Содержит идентификатор текущей строки но не строку. Соответственно: "ТЗСвязаннаяСТаблПолем.Индекс(Элементы.Погрузки.ТекущаяСтрока)" = -1

(11) а блин соррь. Я проглядел, что это 8.2 (. Это все по 8.1 было.

+(12) хотя должно работать. Щаз у ся на демке потестю для опыта

(5) "под свой случай думаю сам доведешь"

Не, вижу не доведешь :) -1 и +1 (с проверкой) сделать не в силах?

Элементы.СписокФайлов.ТекущаяСтрока (число)
Индекс текущей строки, начинается помоему с 0
Соответственно поднять вверх
Элементы.СписокФайлов.ТекущаяСтрока=Элементы.СписокФайлов.ТекущаяСтрока - 1;
опустить вниз
Элементы.СписокФайлов.ТекущаяСтрока=Элементы.СписокФайлов.ТекущаяСтрока + 1;
Проверяй на начало и конец

(15) + 1
для ТЧ
&НаКлиенте
Процедура НаСтрокуВниз(Команда)
   Элементы.Товары.ТекущаяСтрока=Элементы.Товары.ТекущиеДанные.НомерСтроки;    
КонецПроцедуры

&НаКлиенте
Процедура НаСтрокуВВерх(Команда)
   Элементы.Товары.ТекущаяСтрока=Элементы.Товары.ТекущиеДанные.НомерСтроки-2;
КонецПроцедуры

Народ. Вы разницу между индексом строки и идентификатором строки различаете?

(15) Нет.

(15) 1 строка может быть с идентификаторм и 300 и 400.

"Давайте я попробую объяснить вам на таблицах первого уровня (чтобы не загромождать объяснение), а вы уже сами сделаете то же самое для других таблиц.

Дело в том, что таблица, которая в форме, элемент формы, и таблица, которая в реквизите (ДанныеФормыКоллекция) - это разные таблицы. Это две разные коллекции.

Они, конечно, однозначно связаны между собой. То есть зная строку одной таблицы можно получить соответствующую ей строку другой таблицы.

Но эта связь не такая, как вы ее себе представляете:

ГлавнаяТаблицаЗначений[Элементы.ГлавнаяТаблицаЗначений.ТекущаяСтрока]
ТекущаяСтрока у таблицы в форме это не индекс таблицы в реквизите.



Эти две таблицы связаны через Идентификатор.

У таблицы в форме идентификатор можно получить как раз через текущую строку:

Идентификатор = Элементы.ГлавнаяТаблицаЗначений.ТекущаяСтрока;
У таблицы в реквизите (ДанныеФормыКоллекция) есть метод НайтиПоИдентификатору(Идентификатор), который вернет вам строку, соответствующую текущей строке в таблице формы.

В обратную сторону аналогично. Если вы знаете строку у таблицы в реквизите, вы можете найти (или установить курсор на) строку, соответствующую ей в таблице в форме.

У строки таблицы в реквизите (ДанныеФормыЭлементКоллекции) есть метод ПолучитьИдентификатор():

Идентификатор = СтрокаГлавнойТаблицыЗначений.ПолучитьИдентификатор();
А у таблицы в форме - известное уже свойство ТекущаяСтрока:

Элементы.ГлавнаяТаблицаЗначений.ТекущаяСтрока = Идетнификатор;


Таким образом перед выполнением манипуляций вам нужно узнать, какая строка в таблице реквизита соответствует текущей строке в таблице формы. Каким-то образом запомнить, что это за строка.

После выполнения манипуляций в таблице реквизита вам нужно найти эту запомненную строку, получить ее идентификатор и таблице в форме сказать, что ее текущая строка должна быть равна этому идентификатору."

(с) Максим Радченко, 1С

(20) Во правильная статья. А мне все индекс, индекс. +1, -1.

Я тебе еще в (5) отписывал код с определением текущей строки ТЧ, но ты же не слушаешь.

(22) Да как текщую строку определить я знаю. Мне пример тот ничего нового не дал.
Ну определил я текущую строку. Узнал что у нее идентификатор 300, следущая строка идет с идентификатором 512. Мне какой смысл от текущей строки или от идентификаторм 300?

(22) Мне же нужно узнать что за ткущей строкой идет строка с идентификатором 512.

(24) задачку целиком опиши
что за форма, что за таблица, что за данные в ней
вопрос актуальный, результат востребованный

(24) Бррр, а вот так в первой строчке кода написать?

ИдентификаторСтроки = Элементы.Погрузки.ТекущаяСтрока -1;

(26) ОК. Идет заполнение строк таблицы^
Перваоя строка - идентификатор 0
Вторая строка - иднетификатор 1
Третья строка - идентификатор 2

После, удаляем "Вторую строку", при этом идентификаторы не сбиваются. Вот с этим путать не нужно. Получиться:

Первоя строка - идентификатор 0
Вторая строка (была Третья строка) - идентификатор 2

По примеру: Текущая трока "Первоя строка" получаю идентификатор 0. Прибавляю 1. Получаю идентификатор 1 (уже не существующей строки). В результате Error.

(27) "По примеру: Текущая трока "Первоя строка" получаю идентификатор 0. Прибавляю 1. Получаю идентификатор 1 (уже не существующей строки). В результате Error."

Да ты почитай внимательно, ты получаешь сначала следующую строку от текущей, а затем только определяешь ее идентификатор, а не наоборот.

Все оказалось проще. Это для следующей строки:

&НаКлиенте
Процедура Пред(Команда)
   Если Элементы.Погрузки.ТекущиеДанные.НомерСтроки < Объект.Погрузки.Количество() Тогда
       ИндексЭлементаКоллекции = Объект.Погрузки.Получить(Элементы.Погрузки.ТекущиеДанные.НомерСтроки);
       Элементы.Погрузки.ТекущаяСтрока = ИндексЭлементаКоллекции.ИсходныйНомерСтроки-1;
   КонецЕсли;
КонецПроцедуры

(29) Реквизита "НомерСтроки" может и не быть ...
Я вроде бы разобрался с тонкостями работы с ТЗ на форме, делаю так:

&НаКлиенте
Процедура КурсорВниз(Команда)
   ИндексТекущегоЭлементаКоллекции = ТЗОбъект.Индекс(Элементы.ТЗОбъект.ТекущиеДанные);
   КоличествоЭлементовКоллекции = ТЗОбъект.Количество();
   Если ИндексТекущегоЭлементаКоллекции < КоличествоЭлементовКоллекции - 1 Тогда
       Элементы.ТЗОбъект.ТекущаяСтрока = ТЗОбъект[ИндексТекущегоЭлементаКоллекции+1].ПолучитьИдентификатор();
   Иначе
       Сообщить("Низя!");
   КонецЕсли;
КонецПроцедуры

&НаКлиенте
Процедура КурсорВверх(Команда)
   ИндексТекущегоЭлементаКоллекции = ТЗОбъект.Индекс(Элементы.ТЗОбъект.ТекущиеДанные);
   Если ИндексТекущегоЭлементаКоллекции > 0  Тогда
       Элементы.ТЗОбъект.ТекущаяСтрока = ТЗОбъект[ИндексТекущегоЭлементаКоллекции-1].ПолучитьИдентификатор();
   Иначе
       Сообщить("Низя!");
   КонецЕсли;
КонецПроцедуры

(30) "Реквизита "НомерСтроки" может и не быть ..."

Это в каком случае?

(31) Создайте реквизит формы ТЗ типа "ТаблицаЗначений" к примеру с одним столбцом типа текст. Перетащите ТЗ1 в Элементы, что бы она отображалась на форме.

В таком случае Элементы.ТЗ1.ТекущиеДанные.НомерСтроки - "Поле объекта не определено ..." хотя Элементы.ТЗ1.ТекущиеДанные определено и содержит ДанныеФормыЭлементКоллекции

(32) Логично, но это потому что в ТЗ данных то нет, поэтому и неопределено, как только данные появятся и НомерСтроки, или я не прав (1С нет под рукой сейчас)?

*как только данные появятся, появится и НомерСтроки

(34) Не появиться, несколько раз проверял на НЕ пустой ТЗ ) ...
У Типа ДанныеФормыЭлементКоллекции нет встроенного свойства НомерСтроки, его свойства зависят от объекта которые он моделирует. Если он фактически ничего не моделирует, как в описанном ной случае, то и свойства такого у него нет.
Из синтаксис-помощника:
"Описание:
Набор свойств элемента коллекции зависит от того, на основе какого объекта построена данная коллекция. Может включать в себя свойства, значениями которых будут являться другие универсальные структуры, универсальные коллекции и наборы записей."
Но Вы всё равно проверьте, 8.2 такая штука - никому не верь, даже собственным глазам )