Привет, помогите как в запросе проверить заполнена ли табличная часть в документе

Например, с помощью ИМЕЮЩИЕ

Я бы с помощью КОЛИЧЕСТВО проверил

Если есть левое соединение с ней - можно проверить на Null.

А через КОЛИЧЕСТВО попотробней можно?

ВЫБРАТЬ
   ЕСТЬNULL(ВложенныйЗапрос.КоличествоСтрок, 0) КАК СтрокВТабЧасти
ИЗ
   Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
       ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
           РеализацияТоваровУслугТовары.Ссылка КАК Ссылка,
           СУММА(1) КАК КоличествоСтрок
       ИЗ
           Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслугТовары
       
       СГРУППИРОВАТЬ ПО
           РеализацияТоваровУслугТовары.Ссылка) КАК ВложенныйЗапрос
       ПО РеализацияТоваровУслуг.Ссылка = ВложенныйЗапрос.Ссылка

ВЫБРАТЬ
   КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ОтчетОРозничныхПродажахТовары.НомерСтроки) КАК НомерСтроки,
   ОтчетОРозничныхПродажахТовары.Ссылка
ИЗ
   Документ.ОтчетОРозничныхПродажах.Товары КАК ОтчетОРозничныхПродажахТовары
ГДЕ
   ОтчетОРозничныхПродажахТовары.Ссылка.Дата МЕЖДУ &ДатаНач И &ДатаКон

СГРУППИРОВАТЬ ПО
   ОтчетОРозничныхПродажахТовары.Ссылка

ИМЕЮЩИЕ
   КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ОтчетОРозничныхПродажахТовары.НомерСтроки) > 0

способ в (3) лучше

(7) Без разницы. Зато можно сразу и количество строк узнать, если нужно

Все понял большое спасибо

(5) Если уж считать количество, то зачем вложенный запрос?
Не проще ли:

ВЫБРАТЬ
   ЗаказПокупателя.Ссылка КАК Ссылка,
   КОЛИЧЕСТВО(ЗаказПокупателяТовары.Ссылка) КАК КоличествоСтрок
ИЗ
   Документ.ЗаказПокупателя КАК ЗаказПокупателя
       ЛЕВОЕ СОЕДИНЕНИЕ Документ.ЗаказПокупателя.Товары КАК ЗаказПокупателяТовары
       ПО (ЗаказПокупателяТовары.Ссылка = ЗаказПокупателя.Ссылка)

СГРУППИРОВАТЬ ПО
   ЗаказПокупателя.Ссылка

Еще вариант (без доп. соединений и группировок):
ВЫБРАТЬ
   МойДокумент.Ссылка,
   ВЫБОР
       КОГДА 1 В
               (ВЫБРАТЬ ПЕРВЫЕ 1
                   1
               ИЗ
                   Документ.МойДокумент.МояТЧ КАК МояТЧ
               ГДЕ
                   МояТЧ.Ссылка = МойДокумент.Ссылка)
           ТОГДА ИСТИНА
       ИНАЧЕ ЛОЖЬ
   КОНЕЦ КАК ЕстьТЧ
ИЗ
   Документ.МойДокумент КАК МойДокумент