Пишу код:

   Для каждого ЭМ из МассивРегистров цикл
       ОбработкаПрерыванияПользователя();
       НаборЗаписей = РегистрыСведений[ЭМ].СоздатьНаборЗаписей();
       НаборЗаписей.Прочитать();
       если НаборЗаписей.Количество()>0 тогда
           ЗаписатьXML(ЗаписьXML, НаборЗаписей);
       КонецЕсли;
       
   КонецЦикла;

Набор всегда пустой. Что не так?

а что такое МассивРегистров

МассивРегистров = Новый Массив;
   МассивРегистров.Добавить("ПервоначальныеСведенияОСБухгалтерскийУчет");
   МассивРегистров.Добавить("МестонахождениеОСБухгалтерскийУчет");
   МассивРегистров.Добавить("ПараметрыАмортизацииОСБухгалтерскийУчет");
   МассивРегистров.Добавить("ГрафикиАмортизацииОСБухгалтерскийУчет");
   МассивРегистров.Добавить("СпособыОтраженияРасходовПоАмортизацииОСБухгалтерскийУчет");

ну и подумй тогда что ты пишешь?
Чтобы прочитать набор его надо найти, получить

Нужно установить отбор и прочитать.
Что значит получить?

если бы ты написал так, тогда другое дело

   Для каждого ЭМ из МассивРегистров цикл
       ОбработкаПрерыванияПользователя();
       Менеджер = РегистрыСведений[ЭМ];
   Выборка = Менеджер.Выбрать(Отбор);

   Пока Выборка.Следующий() Цикл
       
       Менеджер1 = Выборка.ПолучитьМенеджерЗаписи();
       Менеджер1.Прочитать();
           ЗаписатьXML(ЗаписьXML, Менеджер1);
       КонецЦикла;
   КонецЦикла;

Выбрать * из РегистрСведений.ИмяРегистра

Хотя это один фиг не поможет - их же еще явно надо будет куда-то записывать потом :)

(5)
А ОТБОР какой?

В (2) все регистры подчинены регистратору, поэтому необходимо для получения наборов записей перед НаборЗаписей.Прочитать(); установить отбор по регистратору, ну а для этого сначала отобрать те регистраторы, наборы записей по которым надо выгружать.

...и по каждому получать свой набор записей отдельно...

инструкция тебе в помощь. Хоть немного подумай.
За тебя никто ничего писать не будет. Мысль я тебе дал.
в (6) тоже изложена, только там потом надо будет немного дописать чтобы записать набор.

(10) не думаю что ты мне новое сообщил. Про отбор я и так знаю. Я хотел без отбора прочесть все))

если никто тебе не сообщил новое, тогда вообще для чего ты здесь? задай себе вопрос.
Ты же все знаешь и умеешь.
Тему можно закрывать

(12) вот как получилось

   МассивРегистров = Новый Массив;
   МассивРегистров.Добавить("ПервоначальныеСведенияОСБухгалтерскийУчет");
   МассивРегистров.Добавить("МестонахождениеОСБухгалтерскийУчет");
   МассивРегистров.Добавить("ПараметрыАмортизацииОСБухгалтерскийУчет");
   МассивРегистров.Добавить("ГрафикиАмортизацииОСБухгалтерскийУчет");
   МассивРегистров.Добавить("СпособыОтраженияРасходовПоАмортизацииОСБухгалтерскийУчет");
   
   Для каждого ЭМ из МассивРегистров цикл
       ОбработкаПрерыванияПользователя();
       МенеджерНабораЗаписей = РегистрыСведений[ЭМ];
       
       Запрос = Новый Запрос("ВЫБРАТЬ ПЕРВЫЕ 1 * ИЗ РегистрСведений." + ЭМ);
       РезультатЗапросаПоСоставу = Запрос.Выполнить();
       Если РезультатЗапросаПоСоставу.Пустой() Тогда
           продолжить
       КонецЕсли;
       КолонкиРегистра = РезультатЗапросаПоСоставу.Колонки;
       // выгрузка регистров осуществляется через его набор записей
       НаборЗаписей = МенеджерНабораЗаписей.СоздатьНаборЗаписей();
       Отбор = НаборЗаписей.Отбор;
       СтрокаПолейОтбора = "";
       Для Каждого ЭлементОтбора Из Отбор Цикл
           Если Не ПустаяСтрока(СтрокаПолейОтбора) Тогда
               СтрокаПолейОтбора = СтрокаПолейОтбора + ",";
           КонецЕсли;
           СтрокаПолейОтбора = СтрокаПолейОтбора + ЭлементОтбора.Имя;
       КонецЦикла;
       // строим запрос для выбора из таблицы регистра РАЗЛИЧНЫХ полей отбора
       ТекстЗапроса = "ВЫБРАТЬ РАЗЛИЧНЫЕ " + СтрокаПолейОтбора + " ИЗ РегистрСведений." + ЭМ;
       Запрос.Текст = ТекстЗапроса;
       РезультатЗапросаПоЗначениямОтбора = Запрос.Выполнить();
       ВыборкаИзРезультата = РезультатЗапросаПоЗначениямОтбора.Выбрать();
       
       // читаем наборы записей с различным составом отбора и записываем их
       Пока ВыборкаИзРезультата.Следующий() Цикл
           Для Каждого Колонка Из РезультатЗапросаПоЗначениямОтбора.Колонки Цикл
               Отбор[Колонка.Имя].Значение = ВыборкаИзРезультата[Колонка.Имя];
               Отбор[Колонка.Имя].ВидСравнения = ВидСравнения.Равно;
               Отбор[Колонка.Имя].Использование = Истина;
           КонецЦикла;
           
           НаборЗаписей.Прочитать();
           если НаборЗаписей.Количество()>0 тогда
               ЗаписатьXML(ЗаписьXML, НаборЗаписей);
           КонецЕсли;
           
       КонецЦикла;
   КонецЦикла;

Всем спасибо за участие.

легче нет ничего чем скопировать чужой код, да еще и не разобравшись в нем. Сразу этого сделать нельзя было. :))
ЛЕНЬ ЧЕЛОВЕЧЕСКАЯ ЭТО ппц.

(15) там только фрагмент кода чужой.
А прикрутить нужно тоже уметь.

(13) Сильно.

(16) ну конечно. Верхний цикл поставить ой как сложно ))).
Ты кому рассказываешь то.
(17) просто когда не сильно понимается, что нужно вот и все подряд пишется. И пофиг как, что, зачем это будет.

(18) Если есть время напиши свой вариант - проще. А критиковать много ума не надо.

я тебе написал. и ничем он не отличается.
подумать просто необходимо иногда

(20) ты сколько уже программируешь в 1с?

месяц

а до этого?

что до этого?

(19)
МассивРегистров = Новый Массив;
МассивРегистров.Добавить("ПервоначальныеСведенияОСБухгалтерскийУчет");
МассивРегистров.Добавить("МестонахождениеОСБухгалтерскийУчет");
МассивРегистров.Добавить("ПараметрыАмортизацииОСБухгалтерскийУчет");
МассивРегистров.Добавить("ГрафикиАмортизацииОСБухгалтерскийУчет");
МассивРегистров.Добавить("СпособыОтраженияРасходовПоАмортизацииОСБухгалтерскийУчет");

Запрос = Новый Запрос;
Запрос.Текст =
   "ВЫБРАТЬ
   |    РегистрСведенийПервоначальныеСведенияОСБухгалтерскийУчет.Регистратор КАК Ссылка
   |ИЗ
   |    РегистрСведений.ПервоначальныеСведенияОСБухгалтерскийУчет КАК РегистрСведенийПервоначальныеСведенияОСБухгалтерскийУчет
   |СГРУППИРОВАТЬ ПО
   |    РегистрСведенийПервоначальныеСведенияОСБухгалтерскийУчет.Регистратор
   |
   |ОБЪЕДИНИТЬ
   |
   |ВЫБРАТЬ
   |    РегистрСведенийМестонахождениеОСБухгалтерскийУчет.Регистратор
   |ИЗ
   |    РегистрСведений.МестонахождениеОСБухгалтерскийУчет КАК РегистрСведенийМестонахождениеОСБухгалтерскийУчет
   |СГРУППИРОВАТЬ ПО
   |    РегистрСведенийМестонахождениеОСБухгалтерскийУчет.Регистратор
   |
   |ОБЪЕДИНИТЬ
   |
   |ВЫБРАТЬ
   |    РегистрСведенийПараметрыАмортизацииОСБухгалтерскийУчет.Регистратор
   |ИЗ
   |    РегистрСведений.ПараметрыАмортизацииОСБухгалтерскийУчет КАК РегистрСведенийПараметрыАмортизацииОСБухгалтерскийУчет
   |СГРУППИРОВАТЬ ПО
   |    РегистрСведенийПараметрыАмортизацииОСБухгалтерскийУчет.Регистратор
   |
   |ОБЪЕДИНИТЬ
   |
   |ВЫБРАТЬ
   |    РегистрСведенийГрафикиАмортизацииОСБухгалтерскийУчет.Регистратор
   |ИЗ
   |    РегистрСведений.ГрафикиАмортизацииОСБухгалтерскийУчет КАК РегистрСведенийГрафикиАмортизацииОСБухгалтерскийУчет
   |СГРУППИРОВАТЬ ПО
   |    РегистрСведенийГрафикиАмортизацииОСБухгалтерскийУчет.Регистратор
   |
   |ОБЪЕДИНИТЬ
   |
   |ВЫБРАТЬ
   |    РегистрСведенийСпособыОтраженияРасходовПоАмортизацииОСБухгалтерскийУчет.Регистратор
   |ИЗ
   |    РегистрСведений.СпособыОтраженияРасходовПоАмортизацииОСБухгалтерскийУчет КАК РегистрСведенийСпособыОтраженияРасходовПоАмортизацииОСБухгалтерскийУчет
   |СГРУППИРОВАТЬ ПО
   |    РегистрСведенийСпособыОтраженияРасходовПоАмортизацииОСБухгалтерскийУчет.Регистратор
   |";
ТЗРегистраторы = Запрос.Выполнить().Выгрузить();
Для Каждого ЭМ Из МассивРегистров Цикл
   ОбработкаПрерыванияПользователя();
   Для Каждого ТекСтрока Из ТЗРегистраторы Цикл
       НаборЗаписей = РегистрыСведений[ЭМ].СоздатьНаборЗаписей();
       НаборЗаписей.Отбор.Регистратор.Установить(ТекСтрока.Ссылка);
       НаборЗаписей.Прочитать();
       Если НаборЗаписей.Количество() > 0 Тогда
           ЗаписатьXML(ЗаписьXML, НаборЗаписей);
       КонецЕсли;
   КонецЦикла;
КонецЦикла;

(25) и, в общем случае, XML файл будет меньше.

(25) вот это дело!

Вообщем то, я согласен с SMakcik и писал код в его поддержку. И, думаю, что это надо было бы самому написать - лучше запомнится.

(28) + тебе. :)

(26) (29) спасибо за внимание к моему вопросу.
(26) запрос конечно можно было сгениерировать в несколько строк. Ну да ладно, мы же не на олимпиаде))
Закрываем ветку.