Есть у кого пример, как выгрузить результат компоновки в таблицу значений?

Какие условия должны выполняться для этого?
такая штука выдает "неизвестный тип макета"
----
тз=новый ТаблицаЗначений;

КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиданных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиданных, КомпоновщикНастроек.Настройки);
ПроцессорКомпоновки . Инициализировать (Макеткомпоновки);

ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
ПроцессорВывода.УстановитьОбъект(тз);
ПроцессорВывода.Вывести(ПроцессорКомпоновки);

все, нашел.

(2) поделись по поводу КомпоновщикМакета.Выполнить(,,,?);

(2) Нашел - колись

См. файл V8AddDoc81.htm с дополнениями к документации, который ставится вместе с платформой.

Пример вывода результата компоновки данных в дерево значений:

КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновкиДанных = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных,
      КомпоновщикНастроек.Настройки, , ,
      Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));

ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновкиДанных);

ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
ПроцессорВывода.УстановитьОбъект(ДеревоРезультата);
ПроцессорВывода.НачатьВывод();
Пока Истина Цикл
      ЭлементРезультатаКомпоновкиДанных =
                         ПроцессорКомпоновкиДанных.Следующий();
      Если ЭлементРезультатаКомпоновкиДанных = Неопределено Тогда
                             Прервать;
      КонецЕсли;
      ПроцессорВывода.ВывестиЭлемент(ЭлементРезультатаКомпоновкиДанных);
КонецЦикла;

ПроцессорВывода.ЗакончитьВывод();