Здравствуйте! Подскажите, пожалуйста, как реализовать возможность отметки выбранной строки табличного поля флажком?

что-нибудь пробовали делать для этого?

нет, я просто думаю, как правильнее

я обычно делаю табличную часть с реквизитом булево, а на форме булевый реквизит делаю тип флажок.

нет, у меня это не реквизит

это большое упущение! :)

тогда расказывайте что натворили

на форме документа есть табличное поле - справочникСписок, выбранную строку из него надо отмечать галочкой и запоминать

(6) "запоминать", мадмуазель, означает "сохранить в базу данных".

(7)  :-) Это я учту.

Перем ЗначенияСсылок;

Процедура СправочникСписокПриПолученииДанных(Элемент, ОформленияСтрок)
   
   Для Каждого ОформлениеСтроки Из ОформленияСтрок Цикл
       ДанныеСтроки = ОформлениеСтроки.ДанныеСтроки;
       Если ДанныеСтроки = Неопределено Тогда
           Продолжить;
       Иначе
           Значение = ЗначенияСсылок.Получить(ДанныеСтроки.Ссылка);
           Если Значение = Неопределено Тогда
               Значение = Ложь;
           КонецЕсли;
           ОформлениеСтроки.Ячейки.Флаг.УстановитьФлажок(Значение);
       КонецЕсли;
   КонецЦикла;
   
КонецПроцедуры

Процедура СправочникСписокПриИзмененииФлажка(Элемент, Колонка)
   
   Если Колонка.Имя = "Флаг" Тогда
       Строка = ЭлементыФормы.СправочникСписок.ТекущиеДанные;
       Если Строка <> Неопределено Тогда
           Значение = ЗначенияСсылок.Получить(Строка.Ссылка);
           Если Значение = Неопределено Тогда
               Значение = Ложь;
           КонецЕсли;
           ЗначенияСсылок.Вставить(Строка.Ссылка, Не Значение);
       КонецЕсли;
   КонецЕсли;
   
КонецПроцедуры

ЭлементыФормы.СправочникСписок.Колонки.Добавить("Флаг");
ЗначенияСсылок = Новый Соответствие;

Спасибо!