Туплю я граждане, и чувствую себя идиотом.
Вроде бы примитивная задача, а застрял.
Есть дерево значений на форме. Имя: СоставНоменклатурныхГрупп
Стоит задача удалить строку на которой стоит курсор
Пишу:

ЭлементыФормы.СоставНоменклатурныхГрупп.Значение.Строки.Удалить(ЭлементыФормы.СоставНоменклатурныхГрупп.ТекущаяСтрока);

Ругается: Недопустимое значение параметра 1. Строка не принадлежит коллекции.

Чето не врублюсь я как это победить

для начала:

Дерево = СоставНоменклатурныхГрупп;
Дерево.Строки.Удалить(ЗдесьСтрока);

проверь в отладчике типы данных

Гм. Странно.
Пишу как советовали:

Дерево = СоставНоменклатурныхГрупп;  (без ЭлементыФормы)

Все логично. Возвращает дерево значений.
Пишу дальше:

ЭлементыФормы.СоставНоменклатурныхГрупп.ТекущаяСтрока

(потому что у реквизита формы СоставНоменклатурныхГрупп нет свойства "ТекущаяСтрока", оно есть только у элемента формы)
Проверяю типы. Все правильно:

ЭлементыФормы.СоставНоменклатурныхГрупп.ТекущаяСтрока имеет тип "СтрокаДереваЗначений".

Запускаю и получаю ту же ошибку. Печально :(

P.S. Пардон за оффтопик, как выделять код рамочкой?

(2) про выделение кода - ты не напрягайся. Форум сам всё раскрасит.

*чухаю репу* Гм. А корневой элемент дерева удаляет.

А как по строке дерева определить её индекс?

Так надо.
Функция УдалитьСтрокуДерева(пСтроки, пУдаляемаяСтрока)
   
   Для Каждого Строка из пСтроки Цикл
       Если Строка = пУдаляемаяСтрока Тогда
           пСтроки.Удалить(пУдаляемаяСтрока);
           Возврат Истина;
       КонецЕсли;
       
       // Рекурсивный вызов.
       Результат = УдалитьСтрокуДерева(Строка.Строки, пУдаляемаяСтрока);
       
       Если Результат Тогда
           Возврат Результат;
       КонецЕсли;
   КонецЦикла;
   
   Возврат Ложь;
   
КонецФункции

Ну и вызвать в твоем случае
УдалитьСтрокуДерева(ЭлементыФормы.СоставНоменклатурныхГрупп.Значение.Строки,
                   ЭлементыФормы.СоставНоменклатурныхГрупп.ТекущаяСтрока)

Ага. Спасибо. Заработало.
Хотя я весьма удивлен чесно говоря.
Получается, что что-бы удалить известную строку мало просто вызвать метод Удалить, надо рекурсивно пробедать по дереву, найти эту строку, ещё раз её получить а только потом вызвать этот же самый метод удалить, причем даже с тем-же параметром.
(я бы ещё понял, если бы внутри цикла по строкам надо было вызывать метод "Удалить" с параметром "Строка", а не "пУдаляемаяСтрока").

Спасибо ещё раз.
*Ушел впечатленный*

Можно и проще. Но уже не так круто =))

НужнаяСтрока = ЭлементыФормы.СоставНоменклатурныхГрупп.ТекущаяСтрока
Если НужнаяСтрока.Родитель <> Неопределено Тогда
   НужнаяСтрока.Родитель.Строки.Удалить(НужнаяСтрока);
Иначе
   ЭлементыФормы.СоставНоменклатурныхГрупп.Значение.Строки.Удалить(НужнаяСтрока);
КонецЕсли;