// В начале ГМ:
// 07.04,2025 Для сохранения больших таблиц в Exel-2007
Перем ConnectionXLSX		Экспорт; 
Перем CommandXLSX			Экспорт;

// Можно в конце:
// *************************ФункцииДляСокраненияВ_EXEL-2007****************

Функция ПодготовитьСтрокуКПечати(лСтрока)
	лРез = СокрЛП(лСтрока);
	лРез = СтрЗаменить(лРез,"'","");
	Возврат лРез;
КонецФункции

Функция ЭксельADO_Подключиться(лПутьКФайлу, ЧитЗаг = 0) Экспорт
	Если ЧитЗаг = 0 Тогда
		СтрокаПодключения 			= "
		|Provider=Microsoft.ACE.OLEDB.12.0; 
		|Data Source='" + лПутьКФайлу + "'; 
		|Extended Properties=""Excel 12.0 xml; HDR=YES"";";				   
	Иначе	
		СтрокаПодключения 			= "
		|Provider=Microsoft.ACE.OLEDB.12.0; 
		|Data Source='" + лПутьКФайлу + "'; 
		|Extended Properties=""Excel 12.0 xml; HDR=NO"";";		
	КонецЕсли;
	Попытка
		// Создаем соединение
		ConnectionXLSX			= СоздатьОбъект("ADODB.Connection");
		ConnectionXLSX.Open(СтрокаПодключения);
		CommandXLSX 			= СоздатьОбъект("ADODB.Command");
		CommandXLSX.ActiveConnection = ConnectionXLSX;
		CommandXLSX.CommandType = 1;
	Исключение
		Сообщить("Ошибка подключения к файлу Excel: " + ОписаниеОшибки());
		Возврат 0;
	КонецПопытки;
	Возврат 1;	
КонецФункции

Процедура ЭксельADO_Отключиться() Экспорт
	Состояние("Запись файла");
	CommandXLSX		= 0;
	Попытка
		ConnectionXLSX.Close();
	Исключение
	КонецПопытки;
	ConnectionXLSX 	= 0;
КонецПроцедуры

Функция СоздатьТаблицуСКолонками(ТЗ, ИмяЛиста, БезЗаголовков = 0) Экспорт  // Добавлен параметр БезЗаголовков
	СчКол 		= 0; 
	СтрДанных   = ""; 
	Если (ТЗ.КоличествоСтрок() = 0) И (БезЗаголовков = 1) Тогда
		Возврат 0;	
	КонецЕсли;
	Для СчКол = 1 По ТЗ.КоличествоКолонок() Цикл
		Тип		= "";
		Размер	= "";
		Точн	= "";
		Заг		= "";
		ТЗ.ПолучитьПараметрыКолонки(СчКол, Тип, Размер, Точн, Заг);
		Если БезЗаголовков = 1 Тогда	
			Заг	= СокрЛП(ТЗ.ПолучитьЗначение(1, СчКол));
		КонецЕсли;
		Если Тип = "Число" Тогда
			Если ПустоеЗначение(Точн) = 0 Тогда
				Если Точн > 0 Тогда
					ТипКол	= "float";
				Иначе	
					ТипКол	= "int";
				КонецЕсли;
			Иначе
				ТипКол	= "int";
			КонецЕсли;	
		Иначе
			ТипКол = "char(" + Размер + ")";
		КонецЕсли;
		СтрДанных	= СтрДанных + "[" + Заг + "] " + ТипКол + ", ";
	КонецЦикла;
	СтрДанных		= СокрЛП(СтрДанных);
	ДлинаСтрДанных	= СтрДлина(СтрДанных);
	СтрДанных		= Лев(СтрДанных, ДлинаСтрДанных - 1);
	СтрКоманды	= "CREATE TABLE [" + ИмяЛиста + "] (" + СтрДанных + ")";
	CommandXLSX.CommandText = СтрКоманды;
	CommandXLSX.Execute();	
	Возврат 1;
КонецФункции

Процедура ЭксельADO_ПечатьСтрок(ТЗ, ИмяЛиста, БезЗаголовков = 0, ЕстьШабл = 0) Экспорт
	Перем НазваниеКолонки, ШиринаКолонки, ТипПеременной, ДлинаПеременной,ФорматСтроки;
	Если ТЗ.КоличествоСтрок() = 0 Тогда
		Возврат;
	КонецЕсли;
	ВсегоСтрок	= ТЗ.КоличествоСтрок();	
	СчСтр 		= 0;
	СтарПроц	= 0; 
	Состояние("Идет вывод файла Excel, ожидайте...");
	ТЗ.ВыбратьСтроки();
	Пока ТЗ.ПолучитьСтроку() = 1 Цикл
		СчСтр	= СчСтр + 1;
		Если СчСтр = 1 Тогда
			Если ЕстьШабл = 0 Тогда	
			 	СоздатьТаблицуСКолонками(ТЗ, СокрЛП(ИмяЛиста), БезЗаголовков);
			 	Если БезЗаголовков = 1 Тогда
			 		Продолжить;
			 	КонецЕсли;
		 	КонецЕсли;
		КонецЕсли; 
		ВывСтр	= СчСтр;
		ПроцентВыполнения 	= Окр(ВывСтр / ВсегоСтрок * 100);	
		Если СтарПроц <> ПроцентВыполнения Тогда
			ТекстСостояния 		= Шаблон("Вывод в файл Excel: [ПроцентВыполнения]% ([СчСтр]/[ВсегоСтрок])");	
			Состояние(ТекстСостояния); 
			СтарПроц	= ПроцентВыполнения;
		КонецЕсли;
		лСписокЗначенийКолонок 		= СоздатьОбъект("СписокЗначений");
		лСтрокаПараметров			= "";
		Для НомерКолонки = 1 По ТЗ.КоличествоКолонок() Цикл
			ИдентификаторКолонки 	= ТЗ.ПолучитьПараметрыКолонки(НомерКолонки,ТипПеременной,ДлинаПеременной,,НазваниеКолонки,ШиринаКолонки,ФорматСтроки);
			Если ШиринаКолонки <> -1 Тогда
				ЗначениеЯчейки 		= ТЗ.ПолучитьЗначение(СчСтр,НомерКолонки);
				Если ТипПеременной	= "Число" Тогда
					Если ДлинаПеременной = 1 Тогда					
						лСтрокаПараметров = лСтрокаПараметров + "'" + ?(ЗначениеЯчейки = 0,"ОК", "Ошибка") + "', ";
					Иначе
						ПечЗначение = Формат(ЗначениеЯчейки, ФорматСтроки);
						лСтрокаПараметров = лСтрокаПараметров + ПечЗначение + ", ";
					КонецЕсли;	
				ИначеЕсли ТипПеременной = "Документ" Тогда
					Попытка
						ПечЗначение 	= ЗначениеЯчейки.НомерДок;
					Исключение
						ПечЗначение		= "";
					КонецПопытки;
					лСписокЗначенийКолонок.ДобавитьЗначение();
					лСтрокаПараметров 	= лСтрокаПараметров + "'" + ПодготовитьСтрокуКПечати(ПечЗначение) + "', ";
				ИначеЕсли ТипПеременной	= "Дата" Тогда
					ПечЗначение 		= ?(ПустоеЗначение(ЗначениеЯчейки) = 1, "", Формат(ЗначениеЯчейки,"Д ДДММГГГГ"));
					лСтрокаПараметров 	= лСтрокаПараметров + "'" + ПечЗначение + "', "
				ИначеЕсли ТипПеременной = "Строка" Тогда
					ПечЗначение = СокрЛП(ЗначениеЯчейки);					
					лСтрокаПараметров 	= лСтрокаПараметров + "'" + ПодготовитьСтрокуКПечати(ПечЗначение) + "', ";
				Иначе
					ПечЗначение 		= ЗначениеЯчейки;						
					лСтрокаПараметров 	= лСтрокаПараметров + "'" + ПодготовитьСтрокуКПечати(ПечЗначение) + "', ";
				КонецЕсли;
			КонецЕсли;
		КонецЦикла;	
		лСтрокаПараметров 	= Лев(лСтрокаПараметров, СтрДлина(лСтрокаПараметров) - 2); //убираем последнюю запятую
		CommandXLSX.CommandText = "INSERT INTO [" + ИмяЛиста+ "$] VALUES (" + лСтрокаПараметров + ")";
		CommandXLSX.Execute();
	КонецЦикла;
КонецПроцедуры

Функция Excel2007вТЗ(Файл)	Экспорт
	Рез 						= ЭксельADO_Подключиться(СокрЛП(Файл), 1); // второй параметр - читать заголовки
	Коннект						= ConnectionXLSX;
	axCatalog 					= СоздатьОбъект("ADOX.Catalog");
	axCatalog.ActiveConnection	= ConnectionXLSX;
	ListName					= axCatalog.Tables.Item(0).Name;
	Коннект.CursorLocation 		= 3;  // х.з. за чем, но без этого не верно определяет количество строк на листе...
	ТекстЗапроса 				= "SELECT * FROM [" + ListName + "]";
	RS							= СоздатьОбъект("ADODB.Recordset");
	RS.Open(ТекстЗапроса, Коннект);
	Если (RS.EOF = 1) ИЛИ (RS.BOF = 1) Тогда
		Сообщить("Нет строк в документе Excel!");
		// Закрытие объектов.
		RS.Close();
		ConnectionXLSX.Close();
		RS   			= 0;
		ConnectionXLSX 	= 0;		
	КонецЕсли;
	КолвоКолонокExcel 	= RS.Fields.Count;
	ТЗ 					= СоздатьОбъект("ТаблицаЗначений");
	СчКол				= 0;
	Для СчКол = 1 По КолвоКолонокExcel Цикл
		ИмяКол 			= СокрЛП(RS.Fields.Item(СчКол - 1).value);
		ПозДвоеточия 	= Найти(ИмяКол, ":");
		Если ПозДвоеточия > 0 Тогда
			ИмяКол		= Лев(ИмяКол, ПозДвоеточия - 1);	
		КонецЕсли;
		ИмяКол			= СтрЗаменить(ИмяКол, "-", "");
		ТЗ.НоваяКолонка(ИмяКол);
	КонецЦикла;
	RS.MoveNext();
	КолвоСтрокExcel 	= RS.RecordCount + 1;	
	НомерСтроки = 0;
	Пока RS.EOF() = 0 Цикл
		НомерСтроки	= НомерСтроки + 1;	
		ТЗ.НоваяСтрока();
		СчКол				= 0;
		Для СчКол = 1 По КолвоКолонокExcel Цикл
			ТЗ.УстановитьЗначение(НомерСтроки, СчКол, RS.Fields.Item(СчКол - 1).Value);	
		КонецЦикла;	
		RS.MoveNext();   // СледующаяСтрока.
	КонецЦикла;	
	// Закрытие объектов.
	RS.Close();
	ConnectionXLSX.Close();
	RS   					= 0;
	ConnectionXLSX 			= 0;
	Возврат ТЗ;	
КонецФункции

// Конец********************ФункцииДляСокраненияВ_EXEL-2007****************