Партии поступления для материалов в незавершенном производстве

судя по сообщениям автора, слабоват он на сложные расчеты.
ниже немного другая задача, но это лучше, чем ничего)
ВЫБРАТЬ
	ДоговорыКонтрагентов.Ссылка КАК Договор,
	ДоговорыКонтрагентов.ОсновнойПроект КАК Проект,
	НоменклатурныеГруппы.Ссылка КАК НГ,
	НоменклатурныеГруппы.аркс_ЭтоСтроительныйОбъект
ПОМЕСТИТЬ мСоответсвиеПроектНГ
ИЗ
	Справочник.ДоговорыКонтрагентов КАК ДоговорыКонтрагентов
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.НоменклатурныеГруппы КАК НоменклатурныеГруппы
		ПО ДоговорыКонтрагентов.ОсновнойПроект = НоменклатурныеГруппы.Проект
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
	СУММА(УчетЗатратРегл.Количество) КАК Количество,
	СУММА(УчетЗатратРегл.Стоимость) КАК Стоимость,
	мАналитикаУчетаЗатрат.Затрата,
	УчетЗатратРегл.КодОперации,
	мАналитикаВидаУчета.Склад,
	мАналитикаВидаУчета.СчетУчета
ПОМЕСТИТЬ мСписаниеВПроизводство
ИЗ
	РегистрНакопления.УчетЗатратРегл КАК УчетЗатратРегл
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.АналитикаВидаУчета КАК мАналитикаВидаУчета
		ПО УчетЗатратРегл.АналитикаВидаУчета = мАналитикаВидаУчета.Ссылка
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.АналитикаУчетаЗатрат КАК мАналитикаУчетаЗатрат
		ПО УчетЗатратРегл.АналитикаУчетаЗатрат = мАналитикаУчетаЗатрат.Ссылка
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.АналитикаРаспределенияЗатрат КАК мКорАналитикаРаспределенияЗатрат
		ПО УчетЗатратРегл.КорАналитикаРаспределенияЗатрат = мКорАналитикаРаспределенияЗатрат.Ссылка
ГДЕ
	УчетЗатратРегл.ВидДвижения = ЗНАЧЕНИЕ(ВидДвиженияНакопления.Расход)
	И мАналитикаВидаУчета.РазделУчета = ЗНАЧЕНИЕ(Перечисление.РазделыУчета.МПЗ)
	И мКорАналитикаРаспределенияЗатрат.НоменклатурнаяГруппа В (&НоменклатурнаяГруппа)
	И УчетЗатратРегл.КодОперации = ЗНАЧЕНИЕ(Перечисление.КодыОперацийПартииТоваров.СписаниеПартийВПроизводствоОперативно)

СГРУППИРОВАТЬ ПО
	мАналитикаУчетаЗатрат.Затрата,
	мАналитикаВидаУчета.Склад,
	мАналитикаВидаУчета.СчетУчета,
	УчетЗатратРегл.КодОперации
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
	СУММА(УчетЗатратРегл.Количество) КАК Количество,
	СУММА(УчетЗатратРегл.Стоимость) КАК Стоимость,
	мАналитикаУчетаЗатрат.Затрата,
	УчетЗатратРегл.КодОперации,
	мАналитикаВидаУчета.Склад,
	мАналитикаВидаУчета.СчетУчета
ПОМЕСТИТЬ мПередача
ИЗ
	РегистрНакопления.УчетЗатратРегл КАК УчетЗатратРегл
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.АналитикаВидаУчета КАК мАналитикаВидаУчета
		ПО УчетЗатратРегл.АналитикаВидаУчета = мАналитикаВидаУчета.Ссылка
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.АналитикаУчетаЗатрат КАК мАналитикаУчетаЗатрат
		ПО УчетЗатратРегл.АналитикаУчетаЗатрат = мАналитикаУчетаЗатрат.Ссылка
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.АналитикаРаспределенияЗатрат КАК мКорАналитикаРаспределенияЗатрат
		ПО УчетЗатратРегл.КорАналитикаРаспределенияЗатрат = мКорАналитикаРаспределенияЗатрат.Ссылка
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.АналитикаУчетаПартий КАК мКорАналитикаУчетаПартий
			ВНУТРЕННЕЕ СОЕДИНЕНИЕ мСоответсвиеПроектНГ КАК мСоответсвиеПроектНГ
			ПО мКорАналитикаУчетаПартий.ДоговорКомиссионера = мСоответсвиеПроектНГ.Договор
		ПО УчетЗатратРегл.КорАналитикаУчетаПартий = мКорАналитикаУчетаПартий.Ссылка
ГДЕ
	УчетЗатратРегл.ВидДвижения = ЗНАЧЕНИЕ(ВидДвиженияНакопления.Расход)
	И мАналитикаВидаУчета.РазделУчета = ЗНАЧЕНИЕ(Перечисление.РазделыУчета.МПЗ)
	И мСоответсвиеПроектНГ.НГ В (&НоменклатурнаяГруппа)
	И УчетЗатратРегл.КодОперации = ЗНАЧЕНИЕ(Перечисление.КодыОперацийПартииТоваров.ПередачаВПереработку)

СГРУППИРОВАТЬ ПО
	УчетЗатратРегл.КодОперации,
	мАналитикаВидаУчета.СчетУчета,
	мАналитикаУчетаЗатрат.Затрата,
	мАналитикаВидаУчета.Склад
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
	СУММА(УчетЗатратРегл.Количество) КАК Количество,
	СУММА(УчетЗатратРегл.Стоимость) КАК Стоимость,
	мАналитикаУчетаЗатрат.Затрата,
	УчетЗатратРегл.КодОперации,
	мАналитикаВидаУчета.Склад,
	мАналитикаВидаУчета.СчетУчета
ПОМЕСТИТЬ мРеализация
ИЗ
	РегистрНакопления.УчетЗатратРегл КАК УчетЗатратРегл
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.АналитикаВидаУчета КАК мАналитикаВидаУчета
		ПО УчетЗатратРегл.АналитикаВидаУчета = мАналитикаВидаУчета.Ссылка
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.АналитикаУчетаЗатрат КАК мАналитикаУчетаЗатрат
		ПО УчетЗатратРегл.АналитикаУчетаЗатрат = мАналитикаУчетаЗатрат.Ссылка
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрНакопления.УчетПродажИСебестоимости КАК УчетПродажИСебестоимости
			ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.АналитикаУчетаПартий КАК мАналитикаУчетаПартий
				ВНУТРЕННЕЕ СОЕДИНЕНИЕ мСоответсвиеПроектНГ КАК мСоответсвиеПроектНГ
				ПО мАналитикаУчетаПартий.ДоговорКомиссионера = мСоответсвиеПроектНГ.Договор
			ПО УчетПродажИСебестоимости.АналитикаУчетаПартий = мАналитикаУчетаПартий.Ссылка
		ПО УчетЗатратРегл.Регистратор = УчетПродажИСебестоимости.Регистратор
			И УчетЗатратРегл.НомерСтроки = УчетПродажИСебестоимости.НомерСтроки
ГДЕ
	УчетЗатратРегл.ВидДвижения = ЗНАЧЕНИЕ(ВидДвиженияНакопления.Расход)
	И мАналитикаВидаУчета.РазделУчета = ЗНАЧЕНИЕ(Перечисление.РазделыУчета.МПЗ)
	И УчетЗатратРегл.КодОперации = ЗНАЧЕНИЕ(Перечисление.КодыОперацийПартииТоваров.Реализация)
	И мСоответсвиеПроектНГ.НГ В (&НоменклатурнаяГруппа)

СГРУППИРОВАТЬ ПО
	УчетЗатратРегл.КодОперации,
	мАналитикаВидаУчета.Склад,
	мАналитикаВидаУчета.СчетУчета,
	мАналитикаУчетаЗатрат.Затрата
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	мСписаниеВПроизводство.Склад,
	мСписаниеВПроизводство.СчетУчета,
	мСписаниеВПроизводство.Затрата
ПОМЕСТИТЬ мСписокДляОтбораЗакупок
ИЗ
	мСписаниеВПроизводство КАК мСписаниеВПроизводство

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	мПередача.Склад,
	мПередача.СчетУчета,
	мПередача.Затрата
ИЗ
	мПередача КАК мПередача

ОБЪЕДИНИТЬ

ВЫБРАТЬ
	мРеализация.Склад,
	мРеализация.СчетУчета,
	мРеализация.Затрата
ИЗ
	мРеализация КАК мРеализация
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
	ХозрасчетныйОборотыДтКт.СубконтоКт1 КАК Контрагент,
	ХозрасчетныйОборотыДтКт.СуммаОборот КАК СуммаПриход,
	ХозрасчетныйОборотыДтКт.КоличествоОборотДт КАК КоличествоПриход,
	ХозрасчетныйОборотыДтКт.СубконтоДт1 КАК Склад,
	ХозрасчетныйОборотыДтКт.СубконтоДт2 КАК Затрата,
	ХозрасчетныйОборотыДтКт.СчетДт КАК СчетУчета
ПОМЕСТИТЬ мЗакупка
ИЗ
	РегистрБухгалтерии.Хозрасчетный.ОборотыДтКт(, , Авто, , &СубконтоДТ, , &СубконтоКТ, ) КАК ХозрасчетныйОборотыДтКт
ГДЕ
	(ХозрасчетныйОборотыДтКт.СчетДт, ХозрасчетныйОборотыДтКт.СубконтоДт1, ХозрасчетныйОборотыДтКт.СубконтоДт2) В
			(ВЫБРАТЬ
				Таб.СчетУчета,
				Таб.Склад,
				Таб.Затрата
			ИЗ
				мСписокДляОтбораЗакупок КАК Таб)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	СУММА(Таб.Количество) КАК Количество,
	СУММА(Таб.Стоимость) КАК Стоимость,
	Таб.Затрата,
	Таб.КодОперации,
	мЗакупка.Контрагент,
	СУММА(мЗакупка.СуммаПриход) КАК СуммаПриход,
	СУММА(мЗакупка.КоличествоПриход) КАК КоличествоПриход,
	Таб.Склад,
	Таб.СчетУчета
ИЗ
	(ВЫБРАТЬ
		мСписаниеВПроизводство.Количество КАК Количество,
		мСписаниеВПроизводство.Стоимость КАК Стоимость,
		мСписаниеВПроизводство.Затрата КАК Затрата,
		мСписаниеВПроизводство.КодОперации КАК КодОперации,
		мСписаниеВПроизводство.Склад КАК Склад,
		мСписаниеВПроизводство.СчетУчета КАК СчетУчета
	ИЗ
		мСписаниеВПроизводство КАК мСписаниеВПроизводство
	
	ОБЪЕДИНИТЬ ВСЕ
	
	ВЫБРАТЬ
		мПередача.Количество,
		мПередача.Стоимость,
		мПередача.Затрата,
		мПередача.КодОперации,
		мПередача.Склад,
		мПередача.СчетУчета
	ИЗ
		мПередача КАК мПередача
	
	ОБЪЕДИНИТЬ ВСЕ
	
	ВЫБРАТЬ
		мРеализация.Количество,
		мРеализация.Стоимость,
		мРеализация.Затрата,
		мРеализация.КодОперации,
		мРеализация.Склад,
		мРеализация.СчетУчета
	ИЗ
		мРеализация КАК мРеализация) КАК Таб
		ЛЕВОЕ СОЕДИНЕНИЕ мЗакупка КАК мЗакупка
		ПО Таб.Затрата = мЗакупка.Затрата
			И Таб.Склад = мЗакупка.Склад
			И Таб.СчетУчета = мЗакупка.СчетУчета

СГРУППИРОВАТЬ ПО
	Таб.КодОперации,
	Таб.Затрата,
	мЗакупка.Контрагент,
	Таб.Склад,
	Таб.СчетУчета