В РС, данные на каждый день.
Если я в период выборки ставлю 6 месяцев,
можно ли в запросе задать что бы он отобрал
только первые числа каждого месяца???

||


ВЫБРАТЬ
    КурсыВалют.Период КАК Период,
    КурсыВалют.Валюта КАК Валюта,
    КурсыВалют.Курс КАК Курс,
    КурсыВалют.Валюта.Наименование КАК ВалютаНаименование
ИЗ
    РегистрСведений.КурсыВалют КАК КурсыВалют
ГДЕ
    КурсыВалют.Период МЕЖДУ &НачДата И &КонДата

УПОРЯДОЧИТЬ ПО
    ВалютаНаименование,
    Период

в одном запросе скорее всего нет.
Запрос в цикл и отбирать помесячно не предлагать?

(1) Я так попробовал. Пойдет?



ВЫБРАТЬ
    КурсыВалют.Период КАК Период,
    КурсыВалют.Валюта КАК Валюта,
    КурсыВалют.Курс КАК Курс,
    КурсыВалют.Валюта.Наименование КАК ВалютаНаименование,
    ДЕНЬ(КурсыВалют.Период) КАК День
ПОМЕСТИТЬ ВТ_День
ИЗ
    РегистрСведений.КурсыВалют КАК КурсыВалют
ГДЕ
    КурсыВалют.Период МЕЖДУ &НачДата И &КонДата
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВТ_День.Период КАК Период,
    ВТ_День.Валюта КАК Валюта,
    ВТ_День.Курс КАК Курс,
    ВТ_День.ВалютаНаименование КАК ВалютаНаименование
ИЗ
    ВТ_День КАК ВТ_День
ГДЕ
    ВТ_День.День = 1

УПОРЯДОЧИТЬ ПО
    ВалютаНаименование

ВЫБРАТЬ
    КурсыВалютСрезПоследних.Период,
    КурсыВалютСрезПоследних.Валюта
ИЗ
    РегистрСведений.КурсыВалют.СрезПоследних КАК КурсыВалютСрезПоследних
ГДЕ
    НАЧАЛОПЕРИОДА(КурсыВалютСрезПоследних.Период, МЕСЯЦ) = НАЧАЛОПЕРИОДА(КурсыВалютСрезПоследних.Период, ДЕНЬ)

А если:
ГДЕ ДЕНЬ(КурсыВалют.Период)=1?

+(3) Не уверен насчет срезПоследних. Помоему нужно без него

(2) хммм... хорошая идея. И? Работает?

(4) т.е.
ВЫБРАТЬ
    КурсыВалют.Период КАК Период,
    КурсыВалют.Валюта КАК Валюта,
    КурсыВалют.Курс КАК Курс,
    КурсыВалют.Валюта.Наименование КАК ВалютаНаименование
ИЗ
    РегистрСведений.КурсыВалют КАК КурсыВалют
ГДЕ
    КурсыВалют.Период МЕЖДУ &НачДата И &КонДата
    И ДЕНЬ(КурсыВалют.Период)=1

УПОРЯДОЧИТЬ ПО
    ВалютаНаименование,
    Период

(0) А если первая запись в месяце не первым днем, то
ВЫБРАТЬ РАЗЛИЧНЫЕ
    МЕСЯЦ(КурсыВалют.Период) КАК Мес,
    ГОД(КурсыВалют.Период) КАК Год
ПОМЕСТИТЬ МЕСЯЦ
ИЗ
    РегистрСведений.КурсыВалют КАК КурсыВалют
ГДЕ
    КурсыВалют.Период МЕЖДУ &Н И &К
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    МИНИМУМ(КурсыВалют.Период) КАК Период
ПОМЕСТИТЬ ВТ
ИЗ
    РегистрСведений.КурсыВалют КАК КурсыВалют
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ МЕСЯЦ КАК МЕСЯЦ
        ПО (МЕСЯЦ(КурсыВалют.Период) = МЕСЯЦ.Мес)
            И (ГОД(КурсыВалют.Период) = МЕСЯЦ.Год)

СГРУППИРОВАТЬ ПО
    МЕСЯЦ.Мес,
    МЕСЯЦ.Год
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    КурсыВалют.Период КАК Дата,
    КурсыВалют.Валюта,
    КурсыВалют.Курс,
    КурсыВалют.Валюта.Наименование
ИЗ
    РегистрСведений.КурсыВалют КАК КурсыВалют
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ КАК ВТ
        ПО (НАЧАЛОПЕРИОДА(КурсыВалют.Период, ДЕНЬ) = НАЧАЛОПЕРИОДА(ВТ.Период, ДЕНЬ))

(8) Начало месяца, первым числом же всегда?!!!

(9) Начало месяца действительно первое число.
Но первая запись в РС может быть и 2 и 28 числа.

(10) а почему тогда сделан выбор в пользу срез первых, а не срез последних?

(3) Этот вариант лучше, только без срезПоследних

(11) не использовался срез, но мой вариант не к чему, когда можно как в (3).
Проглядела сначала.

(13) у вас в запросе, по сути, реализован принцип СрезПервых, но в урезанном виде в пределах месяца без использование таблицы СрезПервых.

по мне, вообще лучше для получения периодов, первая ВТ в вашем запросе, использовать производственный календарь.
а дальше срез последних по периодам (реализуется без использования таблицы СрезПоследних, на мисте много таких статей). это будет универсально.

(13) Хотя нет, если записи нет первого числа то месяц выпадает из выборки.
Но это уже смотря какая задача стоит.
Если только 1ое число то да, если первые записи в месяце то (8)

но тут все зависит от поставленной задачи

(14) а пример можно?

(17) Срез последних на каждую дату в запросе Книга знаний: Срез последних на каждую дату в запросе

а какого рода пример надо?

(18) действительно все от задачи зависит.
Если нужны первые записи, то вроде логично что СрезПервых.

пример со СрезПоследних для получения первых записей.

(19) зачем получать срез первых через срез последних?

просто для расчетов с валютой более актуален срез последних (курс на прошедшую дату), чем срез первых (курс на будущую дату)

[code]
ВЫБРАТЬ РАЗЛИЧНЫЕ
    НАЧАЛОПЕРИОДА(КурсыВалют.Период, МЕСЯЦ) КАК НачалоМесяца
ПОМЕСТИТЬ ВТПериоды
ИЗ
    РегистрСведений.КурсыВалют КАК КурсыВалют
ГДЕ
    КурсыВалют.Период МЕЖДУ &ДатаНачала И &ДатаОкончания
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    Периоды.НачалоМесяца,
    МАКСИМУМ(КурсыВалют.Период) КАК ПериодКурса,
    КурсыВалют.Валюта КАК Валюта
ПОМЕСТИТЬ ВТПериодКурса
ИЗ
    ВТПериоды КАК Периоды
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.КурсыВалют КАК КурсыВалют
        ПО Периоды.НачалоМесяца >= КурсыВалют.Период

СГРУППИРОВАТЬ ПО
    Периоды.НачалоМесяца,
    КурсыВалют.Валюта
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВТПериодКурса.НачалоМесяца КАК НачалоМесяца,
    ВТПериодКурса.Валюта КАК Валюта,
    ВТПериодКурса.ПериодКурса КАК ПериодКурса,
    КурсыВалют.Курс,
    КурсыВалют.Кратность
ИЗ
    ВТПериодКурса КАК ВТПериодКурса
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.КурсыВалют КАК КурсыВалют
        ПО ВТПериодКурса.Валюта = КурсыВалют.Валюта
            И ВТПериодКурса.ПериодКурса = КурсыВалют.Период

УПОРЯДОЧИТЬ ПО
    НачалоМесяца,
    Валюта,
    ПериодКурса
[/code]

(20) т.е. если 1ого числа нет курса, то действует последний введенный до 1ого числа, а не следующий (будущий).
Я Вас поняла ). И ведь действительно Вы правы.