Вход | Регистрация
 
1С:Предприятие :: 1С:Предприятие 8 общая

Помогите разобраться с подключением к вебсерверу кассы

Помогите разобраться с подключением к вебсерверу кассы
Я
   URAL
 
18.02.21 - 21:40
Подскажите почему возникает ошибка
    
    ЗаписьJSON = новый ЗаписьJSON;
        
        ЗаписьJSON.УстановитьСтроку();
        
        ЗаписатьJSON(ЗаписьJSON,СтруктураJSON);
        
        СтрокаЗапросаJS = ЗаписьJSON.Закрыть();
        
        HTTPЗапрос.УстановитьТелоИзСтроки(СтрокаЗапросаJS,КодировкаТекста.UTF8);
        
        
        
        Попытка
            
            Соединение = Новый HTTPСоединение("http://127.0.0.1:16732/";);
            
            ОтветHTTP = Соединение.ОтправитьДляОбработки(HTTPЗапрос);
            
        Исключение
            Сообщить("Ошибка ");
            Возврат "Ошибка";
            
        КонецПопытки;



вот тут возникает ошибка ОтветHTTP = Соединение.ОтправитьДляОбработки(HTTPЗапрос);
 
 Партнерская программа EFSOL Oblako
   Ёпрст
 
1 - 18.02.21 - 21:43
выкини http, оставь тока 127.0.0.1 и порт задай параметром
   URAL
 
2 - 18.02.21 - 21:44
Соединение.ОтправитьДляОбработки(HTTPЗапрос)    {<Неизвестный модуль>(1)}: Ошибка при вызове метода контекста (ОтправитьДляОбработки)
   mikecool
 
3 - 18.02.21 - 21:49
(2) тебе про адрес (1) говорит
   mikecool
 
4 - 18.02.21 - 21:49
+3 совсем невдомек, что ли?
   mikecool
 
5 - 18.02.21 - 21:50
и что ты в запрос кладешь, проверь
   Ёпрст
 
6 - 18.02.21 - 21:55
(2)

    Адрес = "127.0.0.1";
    HTTPСоединение = Новый HTTPСоединение(Адрес,16732,,,,,,Ложь);
    HTTPЗапрос = Новый HTTPЗапрос("requests");
    HTTPЗапрос.Заголовки.Вставить("Content-type", "application/json");
    ЗаписьJSON = Новый ЗаписьJSON;
    ЗаписьJSON.ПроверятьСтруктуру = Ложь;
    ЗаписьJSON.УстановитьСтроку();
    Структура =Новый Структура;
    uuid = Новый УникальныйИдентификатор;
    Структура.Вставить("uuid",Строка(uuid));
    Массив = Новый Массив;
    СтруктураЗапроса = Новый Структура;
    СтруктураЗапроса.Вставить("type","getDeviceInfo");
    Массив.Добавить(СтруктураЗапроса);
    Структура.Вставить("request",Массив);
    ЗаписатьJSON(ЗаписьJSON,Структура);
    СтрокаJSON = ЗаписьJSON.Закрыть();
    HTTPЗапрос.УстановитьТелоИзСтроки(СтрокаJSON, КодировкаТекста.UTF8, ИспользованиеByteOrderMark.НеИспользовать);
    HTTPОтвет = HTTPСоединение.ОтправитьДляОбработки(HTTPЗапрос);
    Если HTTPОтвет.КодСостояния = 201 Тогда//успешно поставлено в очередь

        HTTPЗапрос = Новый HTTPЗапрос("requests/"+uuid);
        Ответ = HTTPСоединение.Получить(HTTPЗапрос);
        Если Ответ.КодСостояния = 200 Тогда
            СтрокаОтвета = Ответ.ПолучитьТелоКакСтроку();
                ЧтениеJSON = Новый ЧтениеJSON;
                ЧтениеJSON.УстановитьСтроку(СтрокаОтвета);
                СтруктураОтвета = ПрочитатьJSON(ЧтениеJSON,,"fiscalDocumentDateTime",ФорматДатыJSON.ISO);
                ЧтениеJSON.Закрыть();
             СтатусОперации = СтруктураОтвета.results[0].status;
            Пока СтатусОперации <> "ready" Цикл
                ОбработкаПрерыванияПользователя();
                Если СтатусОперации = "error" Тогда
                     Сообщить("Ошибка получения статуса кассы "+ "errorDescription: "+СтруктураОтвета.results[0].errorDescription +" errorCode: "+СтруктураОтвета.results[0].errorCode);
                     Возврат "errorDescription: "+СтруктураОтвета.results[0].errorDescription +" errorCode: "+СтруктураОтвета.results[0].errorCode;
                КонецЕсли;
                HTTPЗапрос = Новый HTTPЗапрос("requests/"+uuid);
                Ответ = HTTPСоединение.Получить(HTTPЗапрос);
                Если Ответ.КодСостояния = 200 Тогда
                    СтрокаОтвета = Ответ.ПолучитьТелоКакСтроку();
                    ЧтениеJSON = Новый ЧтениеJSON;
                    ЧтениеJSON.УстановитьСтроку(СтрокаОтвета);
                    СтруктураОтвета = ПрочитатьJSON(ЧтениеJSON);
                    
                    СтатусОперации = СтруктураОтвета.results[0].status;
                КонецЕсли;
            КонецЦикла;
            Если СтатусОперации = "error" Тогда
//                 Сообщить("Ошибка получения статуса кассы "+ "errorDescription: "+СтруктураОтвета.results[0].errorDescription +" errorCode: "+СтруктураОтвета.results[0].errorCode);

            ИначеЕсли СтатусОперации = "ready" Тогда
                СостояниеКассы =СтруктураОтвета.results[0].result.deviceInfo;
                Сообщить(СостояниеКассы.configurationVersion);
                //Возврат СостояниеКассы.shift;

                    //closed - закрыта 

                    //opened - открыта 

                    //expired - истекла

            КонецЕсли;            
        КонецЕсли;
    КонецЕсли;


Занимайся

Список тем форума
 
ВНИМАНИЕ! Если вы потеряли окно ввода сообщения, нажмите Ctrl-F5 или Ctrl-R или кнопку "Обновить" в браузере.