Коллеги, ваше мнение. Код такого вид имеет право на жизнь или это говнокод?

(19) Гыгыгыгы
Сначала слей в одну ТЗ а потом Свернуть()

тут нужен мердж
самому такое писать влом ибо нужно быть очень аккуратным

Запросом 44 милисекунды
Кодом 303
Таблица1=Новый ТаблицаЗначений;
    Таблица1.Колонки.Добавить("КолонкаСвязи",Новый ОписаниеТипов("Число",,,Новый КвалификаторыЧисла(15,0)));
    Таблица2=Таблица1.СкопироватьКолонки();
    ГенераторСЧ=Новый ГенераторСлучайныхЧисел();
    Для Счетчик=1 По 10000 Цикл
        НоваяСтрока=Таблица1.Добавить();
        НоваяСтрока.КолонкаСвязи=ГенераторСЧ.СлучайноеЧисло(0,50000);
        НоваяСтрока=Таблица2.Добавить();
        НоваяСтрока.КолонкаСвязи=ГенераторСЧ.СлучайноеЧисло(0,50000);
    КонецЦикла;
    
    Запрос=Новый Запрос;
    Запрос.Текст=
    "ВЫБРАТЬ
    |    Таблица1.КолонкаСвязи КАК КолонкаСвязи
    |ПОМЕСТИТЬ Таблица1
    |ИЗ
    |    &Таблица1 КАК Таблица1
    |;
    |
    ////////////////////////////////////////////////////////////////////////////////

    |ВЫБРАТЬ
    |    Таблица2.КолонкаСвязи КАК КолонкаСвязи
    |ПОМЕСТИТЬ Таблица2
    |ИЗ
    |    &Таблица2 КАК Таблица2
    |;
    |
    ////////////////////////////////////////////////////////////////////////////////

    |ВЫБРАТЬ
    |    Таблица1.КолонкаСвязи КАК КолонкаСвязи,
    |    Таблица2.КолонкаСвязи КАК КолонкаСвязиТаблицы2
    |ИЗ
    |    Таблица1 КАК Таблица1
    |        ЛЕВОЕ СОЕДИНЕНИЕ Таблица2 КАК Таблица2
    |        ПО Таблица1.КолонкаСвязи = Таблица2.КолонкаСвязи";
    
    Запрос.УстановитьПараметр("Таблица1",Таблица1);
    Запрос.УстановитьПараметр("Таблица2",Таблица2);
    ВремяНачала=ТекущаяУниверсальнаяДатаВМиллисекундах();
    Результат=Запрос.Выполнить().Выгрузить();
    ВремяОкночания=ТекущаяУниверсальнаяДатаВМиллисекундах();
    Сообщить("Запросом "+Строка(ВремяОкночания-ВремяНачала));
    
    ВремяНачала=ТекущаяУниверсальнаяДатаВМиллисекундах();
    Таблица1.Сортировать("КолонкаСвязи");
    Таблица1.Колонки.Добавить("КолонкаСвязиТаблицы2");
    Таблица2.Сортировать("КолонкаСвязи");
    ИндексТаблицы1=0;
    ИндексТаблицы2=0;
    Пока Истина Цикл
        СтрокаТаблицы1=Таблица1[ИндексТаблицы1];
        СтрокаТаблицы2=Таблица2[ИндексТаблицы2];
        Если СтрокаТаблицы1.КолонкаСвязи>=СтрокаТаблицы2.КолонкаСвязи Тогда
            ИндексТаблицы2=ИндексТаблицы2+1;
            Если СтрокаТаблицы1.КолонкаСвязи=СтрокаТаблицы2.КолонкаСвязи Тогда
                СтрокаТаблицы1.КолонкаСвязиТаблицы2=СтрокаТаблицы2.КолонкаСвязи;
            КонецЕсли;
        Иначе
            ИндексТаблицы1=ИндексТаблицы1+1;
        КонецЕсли;
        Если ИндексТаблицы1>= Таблица1.Количество() Тогда
            Прервать;
        КонецЕсли;
        Если ИндексТаблицы2>= Таблица2.Количество() Тогда
            Прервать;
        КонецЕсли;        
    КонецЦикла;
    ВремяОкночания=ТекущаяУниверсальнаяДатаВМиллисекундах();
    Сообщить("Кодом "+Строка(ВремяОкночания-ВремяНачала));

(48)+ Сделай плиз просто как в (20)
Все записи из двух ТЗ в одну новую ТЗ из 3-х колонок Справочник1, КоличествоА, КоличествоБ
Пиши 0 где нет значения а затем Свернуть

(39) вот вот, про такие коды я и говорю, индекс шминдекс + 1 ><= и остальные знаки "препинания"
Пока Истина Цикл
        СтрокаТаблицы1=Таблица1[ИндексТаблицы1];
        СтрокаТаблицы2=Таблица2[ИндексТаблицы2];
        Если СтрокаТаблицы1.КолонкаСвязи>=СтрокаТаблицы2.КолонкаСвязи Тогда
            ИндексТаблицы2=ИндексТаблицы2+1;

Если СтрокаТаблицы1.КолонкаСвязи>=СтрокаТаблицы2.КолонкаСвязи Тогда

    // заполнение таблиц для примера

    
    Т1 = Новый ТаблицаЗначений;
    Т1.Колонки.Добавить("а", Новый ОписаниеТипов("Булево"));
    Т1.Колонки.Добавить("б", Новый ОписаниеТипов("Число"));
    
    НовСтр = Т1.Добавить();
    НовСтр.а = Истина;
    НовСтр.б = 1;
    НовСтр = Т1.Добавить();
    НовСтр.а = Ложь;
    НовСтр.б = 2;
    
    
    Т2 = Новый ТаблицаЗначений;
    Т2.Колонки.Добавить("а", Новый ОписаниеТипов("Булево"));
    Т2.Колонки.Добавить("г", Новый ОписаниеТипов("Число"));
    
    НовСтр = Т2.Добавить();
    НовСтр.а = Истина;
    НовСтр.г = 3;
    НовСтр = Т2.Добавить();
    НовСтр.а = Ложь;
    НовСтр.г = 4;
    
    // Собственно говоря сам алгоритм "объединения" таблиц

    
    Т3 = ?(Т1.Количество() > Т2.Количество(), Т1.Скопировать(), Т2.Скопировать());
    Тх = ?(Т1.Количество() > Т2.Количество(), Т2.Скопировать(), Т1.Скопировать());
    Для к = 1 По Тх.Количество() Цикл Т3.Вставить(0); КонецЦикла;
    
    Для к = 0 По Тх.Колонки.Количество()-1 Цикл
        Имя = Тх.Колонки[к].Имя;
        Если Т3.Колонки.Найти(Имя) = Неопределено Тогда
            Т3.Колонки.Добавить(Имя, Тх.Колонки[к].ТипЗначения);
        КонецЕсли;
        Т3.ЗагрузитьКолонку(Тх.ВыгрузитьКолонку(Имя),Имя);
    КонецЦикла;
    
    // чисто для примера работа с "объединенной" таблицей

    
    Т3.Свернуть("а","б,г");
    Т3.ВыбратьСтроку();

Кодом 347

"связывать ТЗ теперь буду на сервере СУБД" +1

Кодом 631
Запросом 157
Моим кодом 357

&НаСервереБезКонтекста
Процедура ТестированиеНаСервере()
    Таблица1=Новый ТаблицаЗначений;
    Таблица1.Колонки.Добавить("КолонкаСвязи",Новый ОписаниеТипов("Число",,,Новый КвалификаторыЧисла(15,0)));
    Таблица1.Колонки.Добавить("КолонкаЗначения",Новый ОписаниеТипов("Число",,,Новый КвалификаторыЧисла(15,0)));
    Таблица2=Таблица1.СкопироватьКолонки();
    ГенераторСЧ=Новый ГенераторСлучайныхЧисел();
    Для Счетчик=1 По 10000 Цикл
        НоваяСтрока=Таблица1.Добавить();
        НоваяСтрока.КолонкаСвязи=ГенераторСЧ.СлучайноеЧисло(0,50000);
        НоваяСтрока.КолонкаЗначения=ГенераторСЧ.СлучайноеЧисло(0,500);
        НоваяСтрока=Таблица2.Добавить();
        НоваяСтрока.КолонкаСвязи=ГенераторСЧ.СлучайноеЧисло(0,50000);
        НоваяСтрока.КолонкаЗначения=ГенераторСЧ.СлучайноеЧисло(0,500);
    КонецЦикла;
    
    ВремяНачала=ТекущаяУниверсальнаяДатаВМиллисекундах();
    Запрос=Новый Запрос;
    Запрос.Текст=
    "ВЫБРАТЬ
    |    Таблица1.КолонкаСвязи КАК КолонкаСвязи,
    |    Таблица1.КолонкаЗначения КАК КолонкаЗначения
    |ПОМЕСТИТЬ Таблица1
    |ИЗ
    |    &Таблица1 КАК Таблица1
    |;
    |
    ////////////////////////////////////////////////////////////////////////////////

    |ВЫБРАТЬ
    |    Таблица2.КолонкаСвязи КАК КолонкаСвязи,
    |    Таблица2.КолонкаЗначения КАК КолонкаЗначения
    |ПОМЕСТИТЬ Таблица2
    |ИЗ
    |    &Таблица2 КАК Таблица2
    |;
    |
    ////////////////////////////////////////////////////////////////////////////////

    |ВЫБРАТЬ
    |    Таблица1.КолонкаСвязи КАК КолонкаСвязи,
    |    Таблица1.КолонкаЗначения КАК КолонкаЗначения1,
    |    Таблица2.КолонкаЗначения КАК КолонкаЗначения2
    |ИЗ
    |    Таблица1 КАК Таблица1
    |        ЛЕВОЕ СОЕДИНЕНИЕ Таблица2 КАК Таблица2
    |        ПО Таблица1.КолонкаСвязи = Таблица2.КолонкаСвязи";
    
    Запрос.УстановитьПараметр("Таблица1",Таблица1);
    Запрос.УстановитьПараметр("Таблица2",Таблица2);
    //ВремяНачала=ТекущаяУниверсальнаяДатаВМиллисекундах();

    Результат=Запрос.Выполнить().Выгрузить();
    ВремяОкночания=ТекущаяУниверсальнаяДатаВМиллисекундах();
    Сообщить("Запросом "+Строка(ВремяОкночания-ВремяНачала));
    
    ВремяНачала=ТекущаяУниверсальнаяДатаВМиллисекундах();
    Таблица1.Сортировать("КолонкаСвязи");
    Таблица1.Колонки.Добавить("КолонкаСвязиТаблицы2");
    Таблица2.Сортировать("КолонкаСвязи");
    ИндексТаблицы1=0;
    ИндексТаблицы2=0;
    Пока Истина Цикл
        СтрокаТаблицы1=Таблица1[ИндексТаблицы1];
        СтрокаТаблицы2=Таблица2[ИндексТаблицы2];
        Если СтрокаТаблицы1.КолонкаСвязи>=СтрокаТаблицы2.КолонкаСвязи Тогда
            ИндексТаблицы2=ИндексТаблицы2+1;
            Если СтрокаТаблицы1.КолонкаСвязи=СтрокаТаблицы2.КолонкаСвязи Тогда
                СтрокаТаблицы1.КолонкаСвязиТаблицы2=СтрокаТаблицы2.КолонкаСвязи;
            КонецЕсли;
        Иначе
            ИндексТаблицы1=ИндексТаблицы1+1;
        КонецЕсли;
        Если ИндексТаблицы1>= Таблица1.Количество() Тогда
            Прервать;
        КонецЕсли;
        Если ИндексТаблицы2>= Таблица2.Количество() Тогда
            Прервать;
        КонецЕсли;        
    КонецЦикла;
    ВремяОкночания=ТекущаяУниверсальнаяДатаВМиллисекундах();
    Сообщить("Кодом "+Строка(ВремяОкночания-ВремяНачала));
    
    
    // Моим кодом

    ВремяНачала=ТекущаяУниверсальнаяДатаВМиллисекундах();
    Таблица3=Новый ТаблицаЗначений;
    Таблица3.Колонки.Добавить("КолонкаСвязи",Новый ОписаниеТипов("Число",,,Новый КвалификаторыЧисла(15,0)));
    Таблица3.Колонки.Добавить("КолонкаЗначения1",Новый ОписаниеТипов("Число",,,Новый КвалификаторыЧисла(15,0)));
    Таблица3.Колонки.Добавить("КолонкаЗначения2",Новый ОписаниеТипов("Число",,,Новый КвалификаторыЧисла(15,0)));
    
    Для Каждого ТекСтр Из Таблица1 Цикл
        НовСтр = Таблица3.Добавить();
        НовСтр.КолонкаСвязи = ТекСтр.КолонкаСвязи;
        НовСтр.КолонкаЗначения1 = ТекСтр.КолонкаЗначения;
        НовСтр.КолонкаЗначения2 = 0;
    КонецЦикла;
    
    Для Каждого ТекСтр Из Таблица2 Цикл
        НовСтр = Таблица3.Добавить();
        НовСтр.КолонкаСвязи = ТекСтр.КолонкаСвязи;
        НовСтр.КолонкаЗначения1 = 0;
        НовСтр.КолонкаЗначения2 = ТекСтр.КолонкаЗначения;
    КонецЦикла;
    
    Таблица3.Свернуть("КолонкаСвязи", "КолонкаЗначения1, КолонкаЗначения2");
    
    ВремяОкночания=ТекущаяУниверсальнаяДатаВМиллисекундах();
    Сообщить("Моим кодом "+Строка(ВремяОкночания-ВремяНачала));
    
КонецПроцедуры

&НаКлиенте
Процедура Тестирование(Команда)
    ТестированиеНаСервере();
КонецПроцедуры

Запросом 157 у Гарри
Запросом 40 у Hadgehogs

Все равно не брошу работать с ТЗ "по месту" :)=

Если надо смержить данных
Все равно на серв не брошу
Буду мержить их руками
Потому что я хороший

(92) Чужое, Сотел

кста на моем рабочем инженернике i7-6400T
Запросом 127
Кодом 198
Моим кодом 114

(94)+ На разогнанном 1650v2
Запросом 173
Кодом 168
Моим кодом 111