Вход | Регистрация
 
1С:Предприятие :: 1С:Предприятие 8 общая

программная печать осв по счету с детализацией

программная печать осв по счету с детализацией
Я
   slasher
 
05.02.21 - 08:41
Добрый день

пытаюсь программно вывести на печать осв по счету, по списку счетов, к примеру счет 60.1,
код примерно такой
        
        ДокументРезультат = Новый ТабличныйДокумент;
    Отчет = Отчеты.ОборотноСальдоваяВедомостьПоСчетуХозрасчетный.Создать();
    Отчет.Организация = Справочники.Организации.НайтиПоКоду("000000015",Истина);
            
    ДокументРезультат.Очистить();
            
    Отчет.Счет = ТекСтрока.Счет;
    Отчет.ДатаНач = ДатаНачала;
    Отчет.ДатаКон = КонецДня(ДатаОкончания);
    Отчет.ПоСубсчетам = Истина;
            
    БухгалтерскиеОтчеты.УстановитьЗапросИОтборПостроителяПоСубконтоДляДвижений(ТекСтрока.Счет, "Хозрасчетный", Отчет.ПостроительОтчета, "Валюта.*");
    //Формируем отчет
    Отчет.СформироватьОтчет(ДокументРезультат, Истина, 5, Ложь);

все бы ничего, но не знаю куда задать настройку, чтобы печать выводилась с детализацией по субконто (Договоры и Контрагенты),
а то отчет выводится как будто свернутый
может кто подскажет?
   zzz_zzz_zzz
 
1 - 05.02.21 - 11:31
В типовой бухии есть функция
БухгалтерскиеОтчетыВызовСервера.СформироватьОтчет()
Поиском по коду можно найти, как передавать ей параметры
   zzz_zzz_zzz
 
2 - 05.02.21 - 11:34
+(1) вот кусок, брал из типовой

    НовыйОтчет = Отчеты.ОборотноСальдоваяВедомостьПоСчету.Создать();
  
    ТабГруппировка = Новый ТаблицаЗначений;
    Для Каждого Реквизит Из НовыйОтчет.Метаданные().ТабличныеЧасти.Группировка.Реквизиты Цикл
        ТабГруппировка.Колонки.Добавить(Реквизит.Имя);
    КонецЦикла;
    ДанныеСчета = БухгалтерскийУчетВызовСервераПовтИсп.ПолучитьСвойстваСчета(Счет);
    Если ДанныеСчета.КоличествоСубконто > 0 Тогда
        НоваяСтрока = ТабГруппировка.Добавить();
        НоваяСтрока.Поле           = "Субконто1";
        НоваяСтрока.Использование  = Истина;
        НоваяСтрока.Представление  = ДанныеСчета.ВидСубконто1Наименование;
        НоваяСтрока.ТипГруппировки = 0;
    КонецЕсли;
    Если ДанныеСчета.КоличествоСубконто > 1 Тогда
        НоваяСтрока = ТабГруппировка.Добавить();
        НоваяСтрока.Поле           = "Субконто2";
        НоваяСтрока.Использование  = Истина;
        НоваяСтрока.Представление  = ДанныеСчета.ВидСубконто2Наименование;
        НоваяСтрока.ТипГруппировки = 0;
    КонецЕсли;
    Если ДанныеСчета.КоличествоСубконто > 2 Тогда
        НоваяСтрока = ТабГруппировка.Добавить();
        НоваяСтрока.Поле           = "Субконто3";
        НоваяСтрока.Использование  = Истина;
        НоваяСтрока.Представление  = ДанныеСчета.ВидСубконто3Наименование;
        НоваяСтрока.ТипГруппировки = 0;
    КонецЕсли;

    ПараметрыОтчета = Новый Структура;
    ПараметрыОтчета.Вставить("Организация"                      , Организация);
    ПараметрыОтчета.Вставить("НачалоПериода"                    , НачалоПериода);
    ПараметрыОтчета.Вставить("КонецПериода"                     , КонецПериода);
    ПараметрыОтчета.Вставить("ВключатьОбособленныеПодразделения", ЛОЖЬ);
    ПараметрыОтчета.Вставить("ПоказательБУ"                     , Истина);
    ПараметрыОтчета.Вставить("ПоказательНУ"                     , ЛОЖЬ);
    ПараметрыОтчета.Вставить("ПоказательПР"                     , ЛОЖЬ);
    ПараметрыОтчета.Вставить("ПоказательВР"                     , ЛОЖЬ);
    ПараметрыОтчета.Вставить("ПоказательВалютнаяСумма"          , ЛОЖЬ);
    ПараметрыОтчета.Вставить("ПоказательКоличество"             , Истина);    
    ПараметрыОтчета.Вставить("ПоказательКонтроль"               , ЛОЖЬ);
    ПараметрыОтчета.Вставить("РазвернутоеСальдо"                , Истина);    
    ПараметрыОтчета.Вставить("РазмещениеДополнительныхПолей"    , 0);
    ПараметрыОтчета.Вставить("Периодичность"            , 0);    
    ПараметрыОтчета.Вставить("Счет"                         , Счет);
    ПараметрыОтчета.Вставить("ПоСубсчетам"                      , Истина);
    ПараметрыОтчета.Вставить("Группировка"                      , ТабГруппировка);
    ПараметрыОтчета.Вставить("ДополнительныеПоля"               , НовыйОтчет.ДополнительныеПоля.Выгрузить());
    ПараметрыОтчета.Вставить("РежимРасшифровки"                 , ЛОЖЬ);
    ПараметрыОтчета.Вставить("ВыводитьЗаголовок"                , Истина);
    ПараметрыОтчета.Вставить("ВыводитьПодвал"                   , ЛОЖЬ);
    ПараметрыОтчета.Вставить("ДанныеРасшифровки"                , Неопределено);
    ПараметрыОтчета.Вставить("МакетОформления"                  , "ОформлениеОтчетовЗеленый");
    ПараметрыОтчета.Вставить("СхемаКомпоновкиДанных"            , НовыйОтчет.ПолучитьМакет("СхемаКомпоновкиДанных"));
    ПараметрыОтчета.Вставить("ИдентификаторОтчета"              , "ОборотноСальдоваяВедомостьПоСчету");
    ПараметрыОтчета.Вставить("НастройкиКомпоновкиДанных"        , НовыйОтчет.КомпоновщикНастроек.ПолучитьНастройки());
    ПараметрыОтчета.Вставить("НаборПоказателей"                 , Отчеты["ОборотноСальдоваяВедомостьПоСчету"].ПолучитьНаборПоказателей());
    ПараметрыОтчета.Вставить("ОтветственноеЛицо"                , Перечисления.ОтветственныеЛицаОрганизаций.ОтветственныйЗаБухгалтерскиеРегистры);
    ПараметрыОтчета.Вставить("ВыводитьЕдиницуИзмерения"         , ЛОЖЬ);
     
    АдресХранилища = ПоместитьВоВременноеХранилище(Неопределено, УникальныйИдентификатор);
    БухгалтерскиеОтчетыВызовСервера.СформироватьОтчет(ПараметрыОтчета, АдресХранилища);

Список тем форума
Рекламное место пустует  Рекламное место пустует
ВНИМАНИЕ! Если вы потеряли окно ввода сообщения, нажмите Ctrl-F5 или Ctrl-R или кнопку "Обновить" в браузере.