как реализовать получение прайса с почты

Профиль = Новый ИнтернетПочтовыйПрофиль;
    
    Если УчетнаяЗаписьЭлектроннойПочты.ВремяОжидания > 0 Тогда
        Профиль.Таймаут = УчетнаяЗаписьЭлектроннойПочты.ВремяОжидания;
    КонецЕсли; 
    
    УстановитьПривилегированныйРежим(Истина);
    Пароли = ОбщегоНазначения.ПрочитатьДанныеИзБезопасногоХранилища(УчетнаяЗаписьЭлектроннойПочты, "Пароль, ПарольSMTP");
    УстановитьПривилегированныйРежим(Ложь);
        
    Если УчетнаяЗаписьЭлектроннойПочты.ПротоколВходящейПочты = "IMAP" Тогда
        Профиль.ПарольIMAP             = Пароли.Пароль;
        Профиль.ПользовательIMAP     = УчетнаяЗаписьЭлектроннойПочты.Пользователь;
        Профиль.ПортIMAP             = УчетнаяЗаписьЭлектроннойПочты.ПортСервераВходящейПочты;
        Профиль.ИспользоватьSSLIMAP = УчетнаяЗаписьЭлектроннойПочты.ИспользоватьЗащищенноеСоединениеДляВходящейПочты;
        Профиль.АдресСервераIMAP     = УчетнаяЗаписьЭлектроннойПочты.СерверВходящейПочты;
    КонецЕсли;    
    
    Если УчетнаяЗаписьЭлектроннойПочты.ПротоколВходящейПочты = "POP3" Тогда
        Профиль.Пароль                 = Пароли.Пароль;
        Профиль.Пользователь         = УчетнаяЗаписьЭлектроннойПочты.Пользователь;
        Профиль.ПортPOP3             = УчетнаяЗаписьЭлектроннойПочты.ПортСервераВходящейПочты;
        Профиль.ИспользоватьSSLPOP3 = УчетнаяЗаписьЭлектроннойПочты.ИспользоватьЗащищенноеСоединениеДляВходящейПочты;
        Профиль.АдресСервераPOP3     = УчетнаяЗаписьЭлектроннойПочты.ПортСервераВходящейПочты;
    КонецЕсли;
        
    Если УчетнаяЗаписьЭлектроннойПочты.ТребуетсяВходНаСерверПередОтправкой Тогда
        Профиль.АдресСервераSMTP     = УчетнаяЗаписьЭлектроннойПочты.СерверИсходящейПочты;
        Профиль.ПортSMTP             = УчетнаяЗаписьЭлектроннойПочты.ПортСервераИсходящейПочты;
        Профиль.ПарольSMTP           = Пароли.ПарольSMTP;
        Профиль.ПользовательSMTP     = УчетнаяЗаписьЭлектроннойПочты.ПользовательSMTP;
        Профиль.ИспользоватьSSLSMTP = УчетнаяЗаписьЭлектроннойПочты.ИспользоватьЗащищенноеСоединениеДляИсходящейПочты
    КонецЕсли; 
    
    ИмяВходящегоФайла = "";
    
    // Попытка создания каталога на диске

    Если ЗначениеЗаполнено(НастройкаОбмена.КаталогНаДиске) Тогда
        Файл = Новый Файл(НастройкаОбмена.КаталогНаДиске);
        Попытка
            Если Не Файл.Существует() Тогда
                СоздатьКаталог(НастройкаОбмена.КаталогНаДиске);
            КонецЕсли;
            КаталогНаДиске = НастройкаОбмена.КаталогНаДиске;
        Исключение
            КаталогНаДиске = КаталогВременныхФайлов();
        КонецПопытки;
    Иначе        
        КаталогНаДиске = КаталогВременныхФайлов();
    КонецЕсли; 
    
    ИмяВходящегоФайла = КаталогНаДиске + НастройкаОбмена.ИмяФайла;
    
    ИнтернетПочта = Новый ИнтернетПочта;
    
    Попытка
        ИнтернетПочта.Подключиться(Профиль, ПротоколИнтернетПочты.IMAP);
    Исключение
        Сообщить("Произошли ошибки при попытке подключения к почтовому ящику!");
        Сообщить(ОписаниеОшибки());

        Возврат "";
    КонецПопытки;
    
    ПараметрыОтбора = Новый Структура;
    ПараметрыОтбора.Вставить("Отправитель", "тест@тест.ru");
    МассивИдентификаторов = ИнтернетПочта.ПолучитьЗаголовки(ПараметрыОтбора);
    МассивПисем = ИнтернетПочта.Выбрать(Ложь, МассивИдентификаторов);
    
    ТЗПисьма = Новый ТаблицаЗначений();
    ТЗПисьма.Колонки.Добавить("Письмо");
    ТЗПисьма.Колонки.Добавить("ДатаОтправления", Новый ОписаниеТипов("Дата", , ,
                                                 Новый КвалификаторыДаты(ЧастиДаты.ДатаВремя)));
    Для каждого Письмо Из МассивПисем Цикл
        СтрокаПисьмо = ТЗПисьма.Добавить();
        СтрокаПисьмо.Письмо = Письмо;
        СтрокаПисьмо.ДатаОтправления = Письмо.ДатаОтправления;    
    КонецЦикла; 
    ТЗПисьма.Сортировать("ДатаОтправления Убыв");
    МассивПисем = ТЗПисьма.ВыгрузитьКолонку("Письмо");
    
    Для Каждого Письмо Из МассивПисем Цикл        
        Если Письмо.Вложения.Количество() > 0 Тогда
            Для каждого ПочтовоеВложение Из Письмо.Вложения Цикл                
                Если СтрНайти(ПочтовоеВложение.ИмяФайла, "кусок имени фала вложения") <> 0 Тогда
                    Попытка
                        ПочтовоеВложение.Данные.Записать(ИмяВходящегоФайла);                    
                    Исключение
                        ИмяВходящегоФайла = "";
                    КонецПопытки;
                    
                    ИнтернетПочта.Отключиться();
                    Возврат ИмяВходящегоФайла;
                КонецЕсли;                
            КонецЦикла;                 
        КонецЕсли;        
    КонецЦикла;    
    
    ИнтернетПочта.Отключиться();
    Возврат ИмяВходящегоФайла;