Вход | Регистрация
 

мобильное приложение (Сканер)

мобильное приложение (Сканер)
Я
   Enot_tut
 
30.10.20 - 11:27
Можно ли стандартными средствами 1с в мобильном приложение сканировать Qr-коды?
   arsik
 
1 - 30.10.20 - 11:45
(0) Можно
   rozer76
 
2 - 30.10.20 - 12:46
&НаКлиенте
Процедура СканироватьКомплектовщика(Команда)
    #Если МобильноеПриложениеКлиент Тогда

        ОбработчикСканирования = Новый ОписаниеОповещения("ОбработкаСканироватьКомплектовщика", ЭтотОбъект);
        ОбработчикЗакрытия = Новый ОписаниеОповещения("ОбработкаЗакрытияИнтерфейса", ЭтотОбъект);
        СредстваМультимедиа.ПоказатьСканированиеШтрихКодов("Считайте QR-код комплектовщика", ОбработчикСканирования, ОбработчикЗакрытия,ТипШтрихКода.Двухмерный);
    #КонецЕсли

КонецПроцедуры

&НаКлиенте
Процедура ОбработкаСканироватьКомплектовщика(Штрихкод, Результат, Сообщение, ДополнительныеПараметры) Экспорт
    #Если МобильноеПриложениеКлиент Тогда

        СредстваМультимедиа.ЗакрытьСканированиеШтрихКодов();
    #КонецЕсли

    Элементы.Инфо.Заголовок = "";
    Если Результат = Истина Тогда
        ВидПечатнойФормы = ОбщийСервер.ОКПолучитьВидПечатнойФормыJSON(Штрихкод);
        Если ВидПечатнойФормы <> "Сотрудник" Тогда
            ПредставлениеQRКомплектовщика = "";
            #Если МобильноеПриложениеКлиент Тогда

                СредстваМультимедиа.ВоспроизвестиЗвуковоеОповещение(,Истина);    
            #КонецЕсли

            ПоказатьПредупреждение(,"ОШИБКА ШТРИХКОДА: Это не QR-код комплектовщика");
            Возврат;
        КонецЕсли;
        ПредставлениеQRКомплектовщика = Штрихкод;
        
        РезультатСтруктура = ЗапросНезавершенныхДокументовКомплектовщика(ПредставлениеQRКомплектовщика);
        Если РезультатСтруктура.Результат = "Ошибка" Тогда
            #Если МобильноеПриложениеКлиент Тогда

                СредстваМультимедиа.ВоспроизвестиЗвуковоеОповещение(,Истина);    
            #КонецЕсли

            ПоказатьПредупреждение(,РезультатСтруктура.Описание);
            Возврат;
        ИначеЕсли РезультатСтруктура.Результат = "ЕстьНезавершенныеДокументы" Тогда    
            #Если МобильноеПриложениеКлиент Тогда

                СредстваМультимедиа.ВоспроизвестиЗвуковоеОповещение(,Истина);    
            #КонецЕсли

            ТекстВопроса = "Есть незавершенные документы: " + РезультатСтруктура.Описание + ".
            |Завершить их и начать новый ?";
            ДополнительныеПараметры = Новый Структура;
            ДополнительныеПараметры.Вставить("ПредставлениеQRНакладной",ПредставлениеQRНакладной);
            ДополнительныеПараметры.Вставить("ПредставлениеQRКомплектовщика",ПредставлениеQRКомплектовщика);
            ДополнительныеПараметры.Вставить("ВидПечатнойФормы",ВидПечатнойФормы);
            ДополнительныеПараметры.Вставить("ВидПечатнойФормыНакладной",ВидПечатнойФормыНакладной);
            ПоказатьВопрос(Новый ОписаниеОповещения("ОбработкаВопросЗапросНезавершенныхДокументовКомплектовщика", ЭтотОбъект, ДополнительныеПараметры), ТекстВопроса, РежимДиалогаВопрос.ДаНет,,,"Есть незавершенные документы");
            Возврат;
        КонецЕсли;
        ВызовРезультатСканироватьКомплектовщикаНаКлиенте(ПредставлениеQRНакладной, ПредставлениеQRКомплектовщика, ВидПечатнойФормы, ВидПечатнойФормыНакладной);
    Иначе
        #Если МобильноеПриложениеКлиент Тогда
            СредстваМультимедиа.ВоспроизвестиЗвуковоеОповещение(,Истина);    
        #КонецЕсли
        ПоказатьПредупреждение(,"QR-код не считан");
    КонецЕсли; 
КонецПроцедуры
   CepeLLlka
 
3 - 30.10.20 - 13:01
(2)Красавчик, спасибо
   stopa85
 
4 - 30.10.20 - 13:41
А кому-нибудь удавалось сканировать сигаретные марки с помощью МП?
   Широкий
 
5 - 30.10.20 - 13:44
(4) Камерой фоткать заведо бред.
ТСДшка нужна на андроиде
   Enot_tut
 
6 - 30.10.20 - 13:45
(2) спасибо, ТипШтрихКода.Двухмерный
   ДедМорроз
 
7 - 31.10.20 - 16:54
Двумерники камерой ещё терпимо,собственно,у тсд в сканере такая же камера,а вот одномерники накладно только из за запуска интерфейса.
   stopa85
 
8 - 31.10.20 - 17:09
(8) Так и их нет проблема от сканировать. Субъективно встроенный в платформу сканер, не читает половину того что читает приложение Честный Знак.

Список тем форума
Рекламное место пустует  Рекламное место пустует
ВНИМАНИЕ! Если вы потеряли окно ввода сообщения, нажмите Ctrl-F5 или Ctrl-R или кнопку "Обновить" в браузере.