Разобрать адрес контрагента на составляющие в СКД

ааа.. общего модуля
Вот и след. вопрос.

ВЫБРАТЬ
    ПартнерыКонтактнаяИнформация.Представление КАК Представление,
    ПартнерыКонтактнаяИнформация.Ссылка КАК Ссылка
ИЗ
    Справочник.Партнеры.КонтактнаяИнформация КАК ПартнерыКонтактнаяИнформация

что в итоге сделал
В вычисляемые поля добавил 
Расш1_РаботаСАдресами.ПолучитьЧастьАдреса( Значение, "Индекс")

А в расширении сделал такую функцию 

Функция ПолучитьЧастьАдреса(Значение, Часть) Экспорт
    
    Если ЗначениеЗаполнено(Значение) Тогда
        Попытка
            ЧтениеJSON = Новый ЧтениеJSON;
            ЧтениеJSON.УстановитьСтроку(Значение);    
            Данные = ПрочитатьJSON(ЧтениеJSON, Ложь);
            ЧтениеJSON.Закрыть();
            
            Если Данные.addressType = "Административно-территориальный" Тогда
                Если Часть = "Улица" Тогда
                    Улица = ?(СтрДлина(Данные.streettype) > СтрДлина(Данные.street), Данные.streettype, Данные.street);
                    Если НЕ ЗначениеЗаполнено(Улица) Тогда
                        Улица = РаботаСАдресами.СведенияОбАдресе(Значение).Улица;
                    КонецЕсли;
                    Возврат Улица;
                ИначеЕсли Часть = "Индекс" Тогда
                    Индекс  = Данные.ZIPcode;
                    Если НЕ ЗначениеЗаполнено(Индекс) Тогда
                        Индекс = РаботаСАдресами.СведенияОбАдресе(Значение).Индекс;
                    КонецЕсли;
                    Возврат Индекс;
                ИначеЕсли Часть = "Регион" Тогда
                    Регион = Данные.area;
                    Если НЕ ЗначениеЗаполнено(Регион) Тогда
                        Регион = РаботаСАдресами.СведенияОбАдресе(Значение).Регион;
                    КонецЕсли;
                    Возврат Регион;
                ИначеЕсли Часть = "НаселенныйПункт" Тогда
                    НаселенныйПункт = ?(Данные.city <> "", Данные.city, Данные.locality);
                    Если НЕ ЗначениеЗаполнено(НаселенныйПункт) Тогда
                        НаселенныйПункт = РаботаСАдресами.СведенияОбАдресе(Значение).НаселенныйПункт;
                    КонецЕсли;
                    Возврат НаселенныйПункт;
                ИначеЕсли Часть = "Дом" Тогда
                    Дом = Данные.houseNumber;
                    Если НЕ ЗначениеЗаполнено(Дом) Тогда
                        Дом = РаботаСАдресами.СведенияОбАдресе(Значение).Здание.Номер;
                    КонецЕсли;
                    Возврат Дом;
                ИначеЕсли Часть = "Корпус" Тогда
                    Корпус = ?(Данные.buildings.Количество(), Данные.buildings[0].number, "");
                    Если НЕ ЗначениеЗаполнено(Корпус) Тогда
                        Корпуса = РаботаСАдресами.СведенияОбАдресе(Значение).Корпуса;
                        Корпус = ?(Корпуса.Количество(), Корпуса[0].Номер, "");
                    КонецЕсли;
                    Возврат Корпус;
                ИначеЕсли Часть = "Помещение" Тогда
                    Помещение = ?(Данные.apartments.Количество(), Данные.apartments[0].number, "");
                    Если НЕ ЗначениеЗаполнено(Помещение) Тогда
                        Помещения = РаботаСАдресами.СведенияОбАдресе(Значение).Помещения;
                        Помещение = ?(Помещения.Количество(), Помещения[0].Номер, "");
                    КонецЕсли;
                    Возврат Помещение;
                КонецЕсли;
                
            КонецЕсли;
        Исключение        
            Возврат РаботаСАдресами.СведенияОбАдресе(Значение)[Часть];        
        КонецПопытки;
    КонецЕсли;
    
    Возврат "";
    
КонецФункции