Вход | Регистрация
 
1С:Предприятие :: 1С:Предприятие 8 общая

СКД, Не отрабатывает расшифровка по Регистратор

СКД, Не отрабатывает расшифровка по Регистратор
Я
   TonyRnD
 
06.11.19 - 12:02
Есть отчет на СКД

ВЫБРАТЬ РАЗРЕШЕННЫЕ
    КатегорииОбъектов.Объект КАК Номенклатура
ПОМЕСТИТЬ ВТНоменклатураГотоваяПродукция
ИЗ
    РегистрСведений.КатегорииОбъектов КАК КатегорииОбъектов
ГДЕ
    КатегорииОбъектов.Категория = &ГотоваяПродукция
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ РАЗЛИЧНЫЕ
    ИнтекоНоменклатураПоступающаяСПолей.Номенклатура,
    ИнтекоНоменклатураПоступающаяСПолей.Культура
ПОМЕСТИТЬ ВТСоответствиеКультураНоменклатура
ИЗ
    РегистрСведений.ИнтекоНоменклатураПоступающаяСПолей КАК ИнтекоНоменклатураПоступающаяСПолей
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
    ПартииТоваровНаСкладахБухгалтерскийУчетОбороты.Регистратор КАК РегистраторКомплСписывающая,
    ПартииТоваровНаСкладахБухгалтерскийУчетОбороты.Номенклатура КАК НоменклатураСписываемая,
    ПартииТоваровНаСкладахБухгалтерскийУчетОбороты.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатурыСписываемая
ПОМЕСТИТЬ ДокументыКомплектацииСписывающиеСемена
ИЗ
    РегистрСведений.КатегорииОбъектов КАК КатегорииОбъектов
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрНакопления.ПартииТоваровНаСкладахБухгалтерскийУчет.Обороты({(&НачалоПериода)}, {(&КонецПериода)}, Авто, ) КАК ПартииТоваровНаСкладахБухгалтерскийУчетОбороты
        ПО (КатегорииОбъектов.Категория = &Семена)
            И КатегорииОбъектов.Объект = ПартииТоваровНаСкладахБухгалтерскийУчетОбороты.Номенклатура
ГДЕ
    ПартииТоваровНаСкладахБухгалтерскийУчетОбороты.Регистратор.Ссылка ССЫЛКА Документ.КомплектацияНоменклатуры
    И ПартииТоваровНаСкладахБухгалтерскийУчетОбороты.КоличествоРасход > 0
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
    ВТСоответствиеКультураНоменклатура.Культура КАК Культура,
    ДокументыКомплектацииПриходующиеТП.Номенклатура КАК Номенклатура,
    ДокументыКомплектацииПриходующиеТП.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
    ДокументыКомплектацииПриходующиеТП.Склад КАК Склад,
    ЗНАЧЕНИЕ(Справочник.ИнтекоПоля.ПустаяСсылка) КАК Поле,
    ДокументыКомплектацииПриходующиеТП.Организация КАК Организация,
    ВЫБОР
        КОГДА ДокументыКомплектацииПриходующиеТП.КоличествоПриход > 0
            ТОГДА ДокументыКомплектацииПриходующиеТП.КоличествоПриход
        ИНАЧЕ 0
    КОНЕЦ КАК ПриходСогласноАктаПереводаСемянВТоварноеЗерно,
    ДокументыКомплектацииПриходующиеТП.Регистратор КАК Регистратор
ИЗ
    РегистрНакопления.ПартииТоваровНаСкладахБухгалтерскийУчет.Обороты({(&НачалоПериода)}, {(&КонецПериода)}, Авто, ) КАК ДокументыКомплектацииПриходующиеТП
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТСоответствиеКультураНоменклатура КАК ВТСоответствиеКультураНоменклатура
        ПО (ВТСоответствиеКультураНоменклатура.Номенклатура = ДокументыКомплектацииПриходующиеТП.Номенклатура)
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТНоменклатураГотоваяПродукция КАК ВТНоменклатураГотоваяПродукция
        ПО (ВТНоменклатураГотоваяПродукция.Номенклатура = ВТСоответствиеКультураНоменклатура.Номенклатура)
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ ДокументыКомплектацииСписывающиеСемена КАК ДокументыКомплектацииСписывающиеСемена
        ПО ДокументыКомплектацииПриходующиеТП.Регистратор = ДокументыКомплектацииСписывающиеСемена.РегистраторКомплСписывающая

Отчет работает, выдает правильные данные. Но при попытке стандартными средствами рашифровка - регистратор - пустая таблица, только шапка. Что делаю не так? Какую-то галку забыл поставить или в коде запроса что-то не так?
 
 
   toypaul
 
1 - 06.11.19 - 14:03
при расшфировке могут переноситься отборы, которые не предназначены для работы в расшифровке. например, отборы на группировке
   toypaul
 
2 - 06.11.19 - 14:06
если не это, то нужно смотреть какой запрос выполняется. с помощью консоли СКД. может по запросу будет что-то понятно
   TonyRnD
 
3 - 13.11.19 - 14:10
Победил. Если кто столкнется с подобной ситуацией. Отменяем автозаполнение, накидываем в компоновке нужные поля

ВЫБРАТЬ РАЗРЕШЕННЫЕ
    КатегорииОбъектов.Объект КАК Номенклатура
ПОМЕСТИТЬ ВТНоменклатураГотоваяПродукция
ИЗ
    РегистрСведений.КатегорииОбъектов КАК КатегорииОбъектов
ГДЕ
    КатегорииОбъектов.Категория = &ГотоваяПродукция

ИНДЕКСИРОВАТЬ ПО
    Номенклатура
;

////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ РАЗРЕШЕННЫЕ РАЗЛИЧНЫЕ
    ИнтекоНоменклатураПоступающаяСПолей.Номенклатура КАК Номенклатура,
    ИнтекоНоменклатураПоступающаяСПолей.Культура
ПОМЕСТИТЬ ВТСоответствиеКультураНоменклатура
ИЗ
    РегистрСведений.ИнтекоНоменклатураПоступающаяСПолей КАК ИнтекоНоменклатураПоступающаяСПолей

ИНДЕКСИРОВАТЬ ПО
    Номенклатура
;

////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ РАЗЛИЧНЫЕ
    ДокиСписанияСемян.Регистратор КАК РегистраторКомплСписывающая
ПОМЕСТИТЬ ВТДокументыСписанияСемян
ИЗ
    РегистрСведений.КатегорииОбъектов КАК КатегорииОбъектов
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрНакопления.ПартииТоваровНаСкладахБухгалтерскийУчет.Обороты({(&НачалоПериода)}, {(&КонецПериода)}, Авто, ) КАК ДокиСписанияСемян
        ПО (КатегорииОбъектов.Категория = &Семена)
            И КатегорииОбъектов.Объект = ДокиСписанияСемян.Номенклатура
ГДЕ
    ДокиСписанияСемян.Регистратор.Ссылка ССЫЛКА Документ.КомплектацияНоменклатуры
    И ДокиСписанияСемян.КоличествоРасход > 0

ИНДЕКСИРОВАТЬ ПО
    РегистраторКомплСписывающая
;

////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ РАЗРЕШЕННЫЕ
    ВТСоответствиеКультураНоменклатура.Культура КАК Культура,
    ДокументыКомплектацииПриходующиеТП.Номенклатура КАК Номенклатура,
    ДокументыКомплектацииПриходующиеТП.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
    ДокументыКомплектацииПриходующиеТП.Склад КАК Склад,
    ЗНАЧЕНИЕ(Справочник.ИнтекоПоля.ПустаяСсылка) КАК Поле,
    ДокументыКомплектацииПриходующиеТП.Организация КАК Организация,
    ДокументыКомплектацииПриходующиеТП.КоличествоПриход КАК ПриходСогласноАктаПереводаСемянВТоварноеЗерно,
    ДокументыКомплектацииПриходующиеТП.Регистратор КАК Регистратор
{ВЫБРАТЬ
    Культура.*,
    Номенклатура.*,
    ХарактеристикаНоменклатуры.*,
    Склад.*,
    Поле.*,
    Организация.*,
    Регистратор.*,
    ПриходСогласноАктаПереводаСемянВТоварноеЗерно}
ИЗ
    РегистрНакопления.ПартииТоваровНаСкладахБухгалтерскийУчет.Обороты({(&НачалоПериода)}, {(&КонецПериода)}, Авто, ) КАК ДокументыКомплектацииПриходующиеТП
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТСоответствиеКультураНоменклатура КАК ВТСоответствиеКультураНоменклатура
        ПО ДокументыКомплектацииПриходующиеТП.Номенклатура = ВТСоответствиеКультураНоменклатура.Номенклатура
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТНоменклатураГотоваяПродукция КАК ВТНоменклатураГотоваяПродукция
        ПО ДокументыКомплектацииПриходующиеТП.Номенклатура = ВТНоменклатураГотоваяПродукция.Номенклатура
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТДокументыСписанияСемян КАК ДокиСписСемена
        ПО ДокументыКомплектацииПриходующиеТП.Регистратор = ДокиСписСемена.РегистраторКомплСписывающая
ГДЕ
    ДокументыКомплектацииПриходующиеТП.КоличествоПриход > 0
{ГДЕ
    ВТСоответствиеКультураНоменклатура.Культура.*,
    ДокументыКомплектацииПриходующиеТП.Номенклатура.*,
    ДокументыКомплектацииПриходующиеТП.ХарактеристикаНоменклатуры.*,
    ДокументыКомплектацииПриходующиеТП.Склад.*,
    ДокументыКомплектацииПриходующиеТП.Организация.*,
    ДокументыКомплектацииПриходующиеТП.Регистратор.*}

Список тем форума
Рекламное место пустует  Рекламное место пустует
ВНИМАНИЕ! Если вы потеряли окно ввода сообщения, нажмите Ctrl-F5 или Ctrl-R или кнопку "Обновить" в браузере.