Вход | Регистрация
 

Копирование документа с другой формой

Копирование документа с другой формой
Я
   Dom26
 
08.10.19 - 15:46
Я при открытии документа внутри открываю другую форму,(не та что по умолчанию в объекте)

Парам = новый Структура("Ключ", Объект.Ссылка);
        Форма=ПолучитьФорму("Документ.SH_ЗапросНаКонтрактацию.Форма.ФормаДокументаАренда",Парам);    
        Форма.владелецформы =          ЭтаФорма;
    
         Форма.Открыть();


существующий документы отркываются нормлаьно а вот если я копирую этот документ то он в новой этой форме открывается пустым , что то надо вставить в ключ другое?
 
 
   Dom26
 
1 - 08.10.19 - 15:57
неужелиприйдется передавать ЗначениеКопирования и в ручную заполнять объект?
   PR
 
2 - 08.10.19 - 15:59
Фу так делать
   runoff_runoff
 
3 - 08.10.19 - 16:06
(0) а основной реквизит задан во второстепенной форме?..
   Dom26
 
4 - 08.10.19 - 16:06
(2) не хотелосьб другой док создавать но форма явно другая нужна
   Dom26
 
5 - 08.10.19 - 16:07
(3) а чем и как?
   runoff_runoff
 
6 - 08.10.19 - 16:10
(5) жирным шрифтом выделен в списке реквзитов формы.. есть там такой?..
   Dom26
 
7 - 08.10.19 - 16:10
(6) естественно, это форма дока просто не по умолчанию
   PR
 
8 - 08.10.19 - 16:14
(4) Ну так переопредели форму, чтобы открывалась другая
   Dom26
 
9 - 08.10.19 - 16:30
(8) так переопределил. фишка в том что когда копирую тот документ который должен открываться с этой другой формы, док пустой - НЕ КОПИРУЕТСЯ видимо что то надо в ключ вставлять другое
   Dom26
 
10 - 08.10.19 - 16:31
(8) ну или может не так переопределил. подскажите как правильнее
   runoff_runoff
 
11 - 08.10.19 - 16:50
(9) у меня все открывается с параметром Ключ.. только я делаю ОткрытьФорму
   hhhh
 
12 - 08.10.19 - 17:09
(10) юзай обработкаПолученияФормы в модуле менеджера


Процедура ОбработкаПолученияФормы(ВидФормы, Параметры, ВыбраннаяФорма, ДополнительнаяИнформация, СтандартнаяОбработка)
    
    Если ВидФормы <> "ФормаОбъекта" Тогда
        Возврат;
    КонецЕсли;

    ВидОперации = Неопределено; 

    Если Параметры.Свойство("Ключ") И ЗначениеЗаполнено(Параметры.Ключ) Тогда
        ВидОперации = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(Параметры.Ключ, "ВидОперации");
    КонецЕсли;

    // Если документ копируется, то вид формы получаем из копируемого документа.

    Если НЕ ЗначениеЗаполнено(ВидОперации) Тогда
        Если Параметры.Свойство("ЗначениеКопирования")
            И ЗначениеЗаполнено(Параметры.ЗначениеКопирования) Тогда
            ВидОперации = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(
                Параметры.ЗначениеКопирования, "ВидОперации");
        КонецЕсли;
    КонецЕсли;

    Если НЕ ЗначениеЗаполнено(ВидОперации) Тогда
        Если Параметры.Свойство("ЗначенияЗаполнения") 
            И ТипЗнч(Параметры.ЗначенияЗаполнения) = Тип("Структура") Тогда
            Если Параметры.ЗначенияЗаполнения.Свойство("ВидОперации") Тогда
                ВидОперации = Параметры.ЗначенияЗаполнения.ВидОперации;
            КонецЕсли;
        КонецЕсли;
    КонецЕсли;
    
    Если ВидОперации = Перечисления.ВидыОперацийАвансовыйОтчет.Командировка Тогда
        СтандартнаяОбработка = Ложь;
        ВыбраннаяФорма = "ФормаДокументаКомандировка";
    КонецЕсли;

КонецПроцедуры

Список тем форума
Рекламное место пустует  Рекламное место пустует
Проблемы невозможно решaть нa том же уровне компетентности, нa котором они возникaют. Альберт Эйнштейн
ВНИМАНИЕ! Если вы потеряли окно ввода сообщения, нажмите Ctrl-F5 или Ctrl-R или кнопку "Обновить" в браузере.