Вход | Регистрация
 
1С:Предприятие :: 1С:Предприятие 7.7 и ранее

v7: как добавить в форму элемента справочника вкладку для размещения на ней новых реквизитов

v7: как добавить в форму элемента справочника вкладку для размещения на ней новых реквизитов
Я
   alpha78
 
29.05.19 - 10:00
здравствуйте уважаемые коллеги, в 1с 77 как добавить в форму элемента справочника вкладку для размещения на ней новых реквизитов, такого элемента формы как вкладка не обнаружил, но в стандартных документах она есть.
спасибо
 
 
   ДенисЧ
 
1 - 29.05.19 - 10:01
Слои используй.
   kubik_live
 
2 - 29.05.19 - 10:08
ИспользоватьЗакладки(1)
   HawkEye
 
3 - 29.05.19 - 10:08
(0) форма.использоватьЗакладку() 
дальше работаешь с закладками как со списком значений
   alpha78
 
4 - 29.05.19 - 10:11
понял спасибо
   alpha78
 
5 - 29.05.19 - 10:11
всем удачи
   NikVars
 
6 - 29.05.19 - 10:16
   Arbuz
 
7 - 29.05.19 - 13:43
//******************************************************************************

// УстановкаВидимостиСлоев(НомерЗакладки)
//

// Параметры:
//  НомерЗакладки

//
// Возвращаемое значение:

//  Нет.
//

// Описание:
//  Устанавливает видимость слоев формы в зависимости от текущей закладки.

//
Процедура УстановкаВидимостиСлоев(НомерЗакладки)
    
    Если НомерЗакладки=1 Тогда
        Форма.ИспользоватьСлой("Шапка,Основной,Подвал");
    Иначе                                                                
        Форма.ИспользоватьСлой("Шапка,ТабличнаяЧасть,Подвал");
    КонецЕсли;       
    
КонецПроцедуры// УстановкаВидимостиСлоев()


//******************************************************************************

// Предопределенная процедура
//

Процедура ПриОткрытии()
 
    //создаем закладки

    Форма.ИспользоватьЗакладки(1);
    Форма.Закладки.ДобавитьЗначение("Шапка");
    Форма.Закладки.ДобавитьЗначение("Табличная часть");
    
    Если Выбран() = 0 Тогда
        // новый документ/эл.справочника открываем на первой закладке

        Форма.Закладки.ТекущаяСтрока(1);
    Иначе
        // записанный документ/эл.справочника открываем на второй закладке

        Форма.Закладки.ТекущаяСтрока(2);
    КонецЕсли;
    
    УстановкаВидимостиСлоев(Форма.Закладки.ТекущаяСтрока());

КонецПроцедуры  // ПриОткрытии()


//******************************************************************************

// Предопределенная процедура
//

// срабатывает при интерактивном нажатии на закладку
//

Процедура ПриВыбореЗакладки(НомерЗакладки, ЗначениеЗакладки)
                        
    УстановкаВидимостиСлоев(Форма.Закладки.ТекущаяСтрока());
    // делаем что-либо в зависимости от номера закладки

    Если НомерЗакладки=2 Тогда
        ОбновитьНадписи();
    КонецЕсли;       
    
КонецПроцедуры// ПриВыбореЗакладки()     

                                                            

это типовые процедуры для работы с закладками
у меня есть еще функция в глобальнике, позволяющая программно переключать закладку, не меняя код типовых модулей, но нужен 1с++. нужно передать контекст открытой формы и номер или название закладки, возвращает номер закладки или 0 если нет такой закладки.


Функция глПереключитьЗакладку(Конт, Закладка) Экспорт
    
    Перем СпЗакладок;// :"СписокЗначений"

    
    Конт.Форма.Закладки.Выгрузить(СпЗакладок);
    
    Если ТипЗначения(Закладка) = 1 Тогда
        Если (СпЗакладок.РазмерСписка() < Закладка)
                ИЛИ (Закладка < 1) Тогда
            Возврат 0;
        КонецЕсли;
    ИначеЕсли ТипЗначения(Закладка) = 2 Тогда
        Закладка = СпЗакладок.НайтиЗначение(Закладка);
        Если Закладка = 0 Тогда
            Возврат 0;
        КонецЕсли;
    Иначе
        Возврат 0;
    КонецЕсли;
    
    Конт.Форма.Закладки.ТекущаяСтрока(Закладка);
    Конт.ПриВыбореЗакладки(Закладка,СпЗакладок.ПолучитьЗначение(Закладка));
    Конт.Форма.Обновить(0);
    Возврат Закладка;
    
КонецФункции
   alpha78
 
8 - 29.05.19 - 13:52
большое спасибо

Список тем форума
Рекламное место пустует  Рекламное место пустует
Компьютеры — это как велосипед. Только для нашего сознания. Стив Джобс
ВНИМАНИЕ! Если вы потеряли окно ввода сообщения, нажмите Ctrl-F5 или Ctrl-R или кнопку "Обновить" в браузере.
Тема не обновлялась длительное время, и была помечена как архивная. Добавление сообщений невозможно.
Но вы можете создать новую ветку и вам обязательно ответят!
Каждый час на Волшебном форуме бывает более 2000 человек.