Доброго времени суток!
Помогите, пожалуйста, составить следующий запрос по вводным:
Есть справочники Пользователи и ПоказателиАктивности, регистр КоэффициентыПоказателейАктивностиПользователей (измерения Пользователь и Показатель, ресурс ЗначениеПоказателя).

Нужна выборка записей вида {Пользователь:ПоказательАктивности:ЗначениеПоказателя}, но на каждого пользователя из регистра надо вывести ВСЕ записи из справочника показателей. Если для какого-то показателя активности для данного пользователя нет записи в регистре, то значение показателя = NULL.

Такое возможно сделать запросом?
Спасибо.

Обычные левые сеодинения

(1) пробовал, не выходит

(2) Я думаю наши отношения уже перешли на новый уровень - не стесняйся, показывай запрос

ВЫБРАТЬ
    СпрПоказатели.Ссылка
ПОМЕСТИТЬ ВТ_Показатели
ИЗ
    Справочник.ТРК_ПоказателиАктивности КАК СпрПоказатели
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ЗначенияПоказателей.Показатель,
    ЗначенияПоказателей.Пользователь,
    ЗначенияПоказателей.Коэффициент,
    ВТ_Показатели.Ссылка
ИЗ
    ВТ_Показатели КАК ВТ_Показатели
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЗначенияПоказателейПоВидамАктивности.СрезПоследних КАК ЗначенияПоказателей
        ПО ВТ_Показатели.Ссылка = ЗначенияПоказателей.Пользователь

(3) Ахаха, я уже писал в это время

Сначала перемножь таблицы Пользователи и Показатели, помести во временную, потом левым соединением к ней цепляй регистр

(4) так надо к Пользователям соединять всё остальное, если нужны все пользователи

(6) тогда вылезут все пользователи, а они мне не нужны

Ну сначала отбери пользователей как тебе надо, потом (46

*Потом (6)

на каждого пользователя, который есть в записях регистра, нужно вывести все записи справочника показателей

Разве (9) (10) <> (4)?

(12)Не равно. Отбери из регистра всех пользователей и скрещивай их со всеми показателями

(12) не то, сам понял))
в общем, сначала выбрать РАЗЛИЧНЫЕ пользователи, потом перемножить, потом...
Сейчас попробую

(13) ага, (14)

(12) Хм, да. Равно упустил момент, что "на каждого пользователя из регистра". Тогда (4) пойдет вполне

(16) не, не подходит. Надо (14)

ВЫБРАТЬ
    СПР_Пользователи.Ссылка КАК Пользователь,
    СПР_ПоказателиАктивности.Ссылка КАК Показатель,
    РС_КоэффициентыПоказателейАктивностиПользователей.ЗначениеПоказателя КАК Значение
ИЗ
    Справочник.Пользователи КАК СПР_Пользователи
    ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ПоказателиАктивности КАК СПР_ПоказателиАктивности
        ПО Истина
    ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.КоэффициентыПоказателейАктивностиПользователей КАК РС_КоэффициентыПоказателейАктивностиПользователей
        ПО СПР_Пользователи.Ссылка = РС_КоэффициентыПоказателейАктивностиПользователей.Пользователь
        И СПР_ПоказателиАктивности.Ссылка = РС_КоэффициентыПоказателейАктивностиПользователей.Показатель

ВЫБРАТЬ РАЗЛИЧНЫЕ
    ЗначенияПоказателейПоВидамАктивности.Пользователь
ПОМЕСТИТЬ ВТ_Пользователи
ИЗ
    РегистрСведений.ЗначенияПоказателейПоВидамАктивности.СрезПоследних(&ДатаСреза, ) КАК ЗначенияПоказателейПоВидамАктивности
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВТ_Пользователи.Пользователь,
    ТРК_ПоказателиАктивности.Ссылка КАК Показатель
ПОМЕСТИТЬ ВТ_Умножение
ИЗ
    ВТ_Пользователи КАК ВТ_Пользователи,
    Справочник.ТРК_ПоказателиАктивности КАК ТРК_ПоказателиАктивности
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВТ_Умножение.Пользователь КАК Пользователь,
    ВТ_Умножение.Показатель КАК Показатель,
    ЕСТЬNULL(ЗначенияПоказателей.Коэффициент, 0) КАК Коэффициент
ИЗ
    ВТ_Умножение КАК ВТ_Умножение
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЗначенияПоказателейПоВидамАктивности.СрезПоследних(&ДатаСреза, ) КАК ЗначенияПоказателей
        ПО ВТ_Умножение.Пользователь= ЗначенияПоказателей.Пользователь
            И ВТ_Умножение.Показатель = ЗначенияПоказателей.Показатель

УПОРЯДОЧИТЬ ПО
    Пользователь,
    Показатель

Сорри, не увидел, что по пользователя из регистра. Но думаю общая идея понятна.

(20) ага, проверяю
так-то (19) дает то, что надо

(20) работает, спасибо
Всем спасибо, (18) и (19) - рабочий запрос