Когда сформированна диаграмма, она маленького размера-половина формы(Поле табличного дока),как диаграмму растощить ее на все поле?

Никак.

Не может быть!?

Постобработкой табличного документа. Что-то типа того:

ЭлементыФормы.Результат.Рисунки[0].Ширина = 500;

Все конечно замечательно но куда это вставит(При формировании компановкой!)!?

Что-то мне подсказывает, что в обработчике кнопки Сформировать, в конце...

(5) та да. Если его нет - сделать.

Все свойства кнопки Сформировать недоступны для редактирования, и обработчик этой кнопки отсутствует(При формировании компановкой)!?

(7) Смотри "Демонстрационная конфигурация "Примеры 8.1"

Короче ни кто не знает!?

Знаем, тебе копировать код или ты сам найдешь.

Копировать,буду очень признателен!

(7) но его можно самому создать

// Процедура СформироватьОтчет
// Осуществляет вывод отчета в табличный документ
Процедура СформироватьОтчет() Экспорт

   // Очистим табличный документ - результат
   ЭлементыФормы.Результат.Очистить();

   // Сгенерируем макет компоновки данных при помощи компоновщика макета
   КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;

   // В качестве схемы компоновки будет выступать схема самого отчета
   // В качестве настроек отчета - текущие настройки отчета
   // Данные расшифровки будем помещать в свойство расширения формы - ДанныеРасшифровки
   МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки, ДанныеРасшифровки);

   // Создадим и инициализируем процессор компоновки
   ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
   ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, ,ДанныеРасшифровки);

   // Создадим и инициализируем процессор вывода результата
   ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
   ПроцессорВывода.УстановитьДокумент(ЭлементыФормы.Результат);

   // Обозначим начало вывода
   ПроцессорВывода.НачатьВывод();

   // Основной цикл вывода отчета
   Пока Истина Цикл

           // Получим следующий элемент результата компоновки
       ЭлементРезультата = ПроцессорКомпоновки.Следующий();

       Если ЭлементРезультата = Неопределено Тогда
           // Следующий элемент не получен - заканчиваем цикл вывода
           Прервать;

       Иначе
           // Элемент получен - выведем его при помощи процессора вывода
           ПроцессорВывода.ВывестиЭлемент(ЭлементРезультата);

       КонецЕсли;

   КонецЦикла;

   // Обозначем завершение вывода
   ПроцессорВывода.ЗакончитьВывод();

КонецПроцедуры

// Процедура ДействияФормыСформировать
// Действие, выполняемое при нажатии пользователя на кнопку "Сформировать"
Процедура ДействияФормыСформировать(Кнопка)

   СформироватьОтчет();

КонецПроцедуры

Процедура ДействияФормыСформировать(Кнопка)
   ЭлементыФормы.Результат.Очистить();
   ОтчетОбъект.СкомпоноватьРезультат(ЭлементыФормы.Результат, ДанныеРасшифровки);
   ЭлементыФормы.Результат.Рисунки[0].Ширина = 500;
КонецПроцедуры